Elixir 中的排列

Question

我正在努力在 Elixir 中创建一个集合的排列。

Permuate([1,2,3])
[[1, 2, 3], [1, 3, 2], [2, 3, 1], [2, 1, 3], [3, 2, 1], [3, 1, 2]]

但是，我提出的每次尝试都以一些类似的版本结束：

[[2, [3, [1]], [1, [3]]], [3, [2, [1]], [1, [2]]], [1, [2, [3]], [3, [2]]]]

或

[[[2, [[3, 1]]], [2, [[1, 3]]]], [[3, [[2, 1]]], [3, [[1, 2]]]],
[[1, [[2, 3]]], [1, [[3, 2]]]]]

几乎就在那里.. 只是需要一些关于使用 Elixir 构建列表的启示。

我的代码如下所示：

defmodule Permutations do
    def permutate_set(s) do
        if Set.size(s) == 1 do
            Set.to_list(s)
        else
            Enum.map(s, fn(a) ->
                Enum.map(permutate_set(Set.delete(s, a)), fn(b) ->
                    [a] ++ [b]
                end)
            end)
        end
    end
end

Answer 1

注意：

• Set is deprecated
• Use MapSet instead

查找所有权限：

defmodule Perms do
  def perms(%MapSet{} = set),
    do: MapSet.to_list(set) |> perms

  def perms([]), do: [[]]

  def perms(l) do
    for h <- l, t <- perms(l -- [h]),
      do: [h|t]
  end
end


defmodule PermsTest do
  use ExUnit.Case
  doctest Perms

  test "find perms from set" do
    assert [[1, 2], [2, 1]] == Perms.perms(MapSet.new([1,2]))
    assert [[1, 2, 3], [1, 3, 2], [2, 1, 3], [2, 3, 1], [3, 1, 2], [3, 2, 1]] == Perms.perms(MapSet.new([1,2,3]))
  end

  test "find perms" do
    assert [[1, 2], [2, 1]] == Perms.perms([1,2])
    assert [[1, 2, 3], [1, 3, 2], [2, 1, 3], [2, 3, 1], [3, 1, 2], [3, 2, 1]] == Perms.perms([1,2,3])
  end
end

Answer 2

我认为这里的问题是您的匿名函数中的变量b 已经是一个列表。通过将其包装在 [] 中，您将使其成为一个包含列表的列表。