将 Ecto 片段提取到变量中

Question

我有一个片段，它是重复的并且相当复杂。我想将它提取到变量/函数中并多次重复使用，而不是多次编写它。这是一个简化的示例，到目前为止我尝试了许多不同的方法：

f = dynamic([u], fragment("order by name desc"))
query = from(u in User)
        |> order_by([u], ^f)
Repo.all(query)

根据documentation，使用dynamic 应该是可能的，但是我尝试在order_by、select、having 或任何我收到类似于以下的错误消息：

(ArgumentError) expected a field as an atom, a list or keyword list in `order_by`, got: `dynamic([u], fragment("order by name desc"))`

我将如何实现它？

---

更新 1

这里有更真实的例子。以下代码有效：

    from(p in Photo,
      join: pv in assoc(p, :v),
      left_join: pl in assoc(p, :l),
      left_join: pc in assoc(p, :c),
      select: %{p | last_activity_at: fragment("greatest(?, ?, ?)", max(p.inserted_at), max(pl.inserted_at), max(pc.inserted_at))},
      group_by: p.id,
      order_by: [desc: fragment("greatest(?, ?, ?)", max(p.inserted_at), max(pl.inserted_at), max(pc.inserted_at))]
    )

但是，我无法通过提取片段或将其与动态或其他方式一起使用来使其工作。

Answer 1

在与Ecto.Query.dynamic/2 相同的文档中有一个order_by 的示例

f = dynamic([u], fragment("order by name desc"))
# order_by = [desc: :name] # why not just this?
order_by = [desc: ^f]
query = from(u in User), order_by: ^order_by
Repo.all(query)

---

对于更新的示例：

order = dynamic(
  [p, pl, pc], 
  fragment(
    "greatest(?, ?, ?)",
    max(p.inserted_at),
    max(pl.inserted_at),
    max(pc.inserted_at)
  )
)

from(
  p in Photo,
  join: pv in assoc(p, :v),
  left_join: pl in assoc(p, :l),
  left_join: pc in assoc(p, :c),
  select: ...,
  group_by: p.id,
  order_by: ^[desc: order]
)

正如文档中所述，

不可能在根之外传递动态。例如，这不起作用：

 from query, order_by: [asc: ^dynamic(...)]

但这会：

from query, order_by: ^[asc: dynamic(...)]