在 Excel 2013 中使用 VBA 模拟使用箭头键移动

Question

我想为 Excel 2013 创建一个 VBA 宏来移动光标。我只是重新映射键盘快捷键，例如我想使用 CTRL+J 而不是向下箭头来向下移动光标。所以我不需要任何花哨的东西，只需一个简单的光标移动。我也想在 VBA 中执行此操作，因此我不需要寻找 Excel 插件或加载项或类似的东西。

如果在“开发人员”选项卡下，我选择“使用相对引用”，然后简单地录制一个向下移动光标的宏，我会得到以下内容，确实移动光标：

ActiveCell.Offset(1, 0).Range("A1").Select

但是，这不是向下箭头的完全模仿。这个子程序/宏将移动到隐藏的行中，这是我不想要的。

以下每个都给我一个“对象不支持此属性或方法”错误：

Selection.MoveDown Unit:=xlCell, Count:=1, Extend:=xlMove
...
Selection.MoveDown Unit:=xlWorksheetCell, Count:=1, Extend:=xlMove
...
Selection.MoveDown xlCell, 1, xlMove
...
Selection.MoveDown xlWorksheetCell, 1, xlMove

以下给我一个语法错误：

Selection.MoveDown(xlWorksheetCell, 1, xlMove)

我可以想象一个适度的宏移动光标，检查新单元格是否被隐藏，如果是，重复直到它不是。但是，我很难相信没有一个命令/方法/等不能像箭头键那样简单轻松地模拟移动光标，忽略隐藏的行/列。例如，我可以在按住控制键的同时使用箭头键进行模仿，例如 Selection.End(xlDown).Select。所以我想尽可能简单地模拟用箭头键移动光标。

（这似乎是一个如此简单的问题，我猜有人曾经问过/回答过这个问题。但是，如果是这样，并且如果您将我的问题标记为重复，请指出原始答案在哪里，因为我已经看过但找不到它。）

Answer 1

不确定你真正想要的是什么，但是这个呢？

Option Explicit

Sub move_right()
NextVisible "Right"
End Sub

Sub move_left()
NextVisible "Left"
End Sub

Sub move_up()
NextVisible "Up"
End Sub

Sub move_down()
NextVisible "Down"
End Sub

Private Sub NextVisible(direction As String)
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Application.EnableEvents = False

Dim i As Long
Dim r As Range
Set r = ActiveCell
For i = 1 To Rows.Count
    On Error Resume Next 'If you're in A1 and try to go up one, it'll error. This skips that error.
    Select Case direction
        Case "Up"
            Set r = r.Offset(-1, 0)
        Case "Down"
            Set r = r.Offset(1, 0)
        Case "Left"
            Set r = r.Offset(0, -1)
        Case "Right"
            Set r = r.Offset(0, 1)
        Case Else
            Set r = r
    End Select
    On Error Goto 0

    If r.EntireRow.Hidden = False And r.EntireColumn.Hidden = False Then
        r.Select
        Exit Sub
    End If
Next i

Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
Application.EnableEvents = True
End Sub

然后，只需为每个人分配一个快捷方式...

因此，按 CTRL+I 会向上移动活动单元格。

Answer 2

最初是作为解决方案编写的，但后来我发现它也有问题。我会留下它，因为其他人已经发表了评论，但请注意它不是解决方案（至少不是目前的形式）。

我找到了另一个网站here，它回答了我的确切问题。以下是建议的解决方案：

Dim rng As Range
Set rng = Range( _
  Cells(ActiveCell.Row + 1, ActiveCell.Column), _
  Cells(Rows.Count, ActiveCell.Column) _
)
rng.SpecialCells(xlCellTypeVisible).Cells(1).Select

但是，经过仔细研究，这确实适用于向下移动，但不适用于向上移动。具体来说，您可以向下移动越过隐藏行，但如果您尝试向上移动越过隐藏行，则向上移动会停止。

向上：

Dim rng As Range
Set rng = Range( _
  Cells(1, ActiveCell.Column), _
  Cells(ActiveCell.Row - 1, ActiveCell.Column) _
)
Dim rw As Long
rw = rng.SpecialCells(xlCellTypeVisible).Areas( _
    rng.SpecialCells(xlCellTypeVisible).Areas.Count _
    ).Row + rng.SpecialCells(xlCellTypeVisible).Areas( _
    rng.SpecialCells(xlCellTypeVisible).Areas.Count).Rows.Count - 1
rng.SpecialCells(xlCellTypeVisible).Cells(rw).Select

对：

Dim rng As Range
Set rng = Range( _
  Cells(ActiveCell.Row, ActiveCell.Column + 1), _
  Cells(ActiveCell.Row, Columns.Count) _
)
rng.SpecialCells(xlCellTypeVisible).Cells(1).Select

左：

Set rng = Range( _
  Cells(ActiveCell.Row, 1), _
  Cells(ActiveCell.Row, ActiveCell.Column - 1) _
)
Dim rw As Long
rw = rng.SpecialCells(xlCellTypeVisible).Areas( _
    rng.SpecialCells(xlCellTypeVisible).Areas.Count _
    ).Column + rng.SpecialCells(xlCellTypeVisible).Areas( _
    rng.SpecialCells(xlCellTypeVisible).Areas.Count).Columns.Count - 1
rng.SpecialCells(xlCellTypeVisible).Cells(rw).Select

我将继续努力，但因为这是我自己对自己问题的回答，如果其他人（比我更了解 VBA）想要采用此解决方案并在您的自己的答案，我完全祝福你这样做。

还要注意，即使对于成功的向下移动，如果行号大于 32766，此解决方案也会产生“溢出”错误。

Answer 3

将快捷键分配给：

Sub MoveDown()
    Application.SendKeys "{DOWN}"
End Sub

Answer 4

要向下移动一个单元格，前提是在隐藏行的位置没有应用过滤器。

Selection.End(xlDown).Select
Selection.End(xlUp).Offset(1).Select