如果不重复，如何突出显示选定的文本？

Question

我正在使用 VBA 脚本（感谢 @MacroPod）在文档中查找所选文本的重复项，并将它们设置为粗体和红色。

我想更新此脚本以查看文本中引用的某些来源是否未在末尾引用。如果该单词不重复，是否有任何方法可以更改所选文本的格式（例如使其变为粉红色）？

Sub MakeBold()
Application.ScreenUpdating = False
With ActiveDocument.Range
    With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Replacement.Font.Bold = True
        .Replacement.Font.ColorIndex = wdRed
        .Text = Selection.Text
        .Replacement.Text = "^&"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .Execute Replace:=wdReplaceAll
    End With
End With
Application.ScreenUpdating = True
End Sub

Answer 1

如果您使用 Word 的引用工具，那将不是问题。也就是说，尝试：

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Text = Selection.Text
    .Forward = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found
    i = i + 1
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
  With .Find
    .Replacement.Text = "^&"
    .Replacement.ClearFormatting
    .Replacement.Font.Bold = True
    If i = 1 Then
      .Replacement.Font.ColorIndex = wdPink
    Else
      .Replacement.Font.ColorIndex = wdRed
    End If
    .Wrap = wdFindContinue
    .Format = True
    .Execute Replace:=wdReplaceAll
  End With
End With
Application.ScreenUpdating = True
MsgBox i & " instances found."
End Sub