列出安装在 Windows 机器上的所有 Web 浏览器

Question

是否有一个 common 方法/api 来列出我的机器（以及每个用户）上安装的所有 Web 浏览器（名称、可执行文件、默认是/否），以及如何找出哪个是默认网络浏览器？

我看过这个问题：How to find all the browsers installed on a machine

在 MSDN 上：How to Register an Internet Browser or Email Client With the Windows Start Menu 声明网络浏览器应该在HKLM\SOFTWARE\Clients\StartMenuInternet（和HKCU）下注册自己

这真的是常见/正确的方法吗？ （如果是的话，有什么可靠的实现吗？）

---

我的目标是创建一个下拉菜单，其中包含用户机器上安装的所有网络浏览器的列表（表示默认设置），并允许用户使用外部网络浏览器之一浏览他的 HTML 文件/URL可用。

Answer 1

你可以做类似的事情

procedure ListRegisteredBrowsers(List: TStrings);
var
  reg: TRegistry;
  ki: TRegKeyInfo;
  i: Integer;
  keyname: string;
  len: DWORD;
begin
  reg := TRegistry.Create;
  try
    reg.RootKey := HKEY_LOCAL_MACHINE;
    if not Reg.KeyExists('\SOFTWARE\Clients\StartMenuInternet') then Exit;
    if not Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', false) then
      raise Exception.Create('ListRegisteredBrowsers: Could not open registry key.');
    if not reg.GetKeyInfo(ki) then
      raise Exception.Create('ListRegisteredBrowsers: Could not obtain registry key information.');
    List.Clear;
    SetLength(keyname, len);
    for i := 0 to ki.NumSubKeys - 1 do
    begin
      len := ki.MaxSubKeyLen + 1;
      if RegEnumKeyEx(reg.CurrentKey, i, PChar(keyname), len, nil, nil, nil, nil) <> ERROR_SUCCESS then
        RaiseLastOSError;
      if reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet\' + keyname, false) then
        List.Add(reg.ReadString(''));
      Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', true);
    end;
  finally
    reg.Free;
  end;
end;

和

function GetDefaultBrowser: string;
var
  reg: TRegistry;
begin
  result := '';
  reg := TRegistry.Create;
  try
    reg.RootKey := HKEY_CURRENT_USER;
    if Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', false) then
      result := reg.ReadString('')
    else
    begin
      reg.RootKey := HKEY_LOCAL_MACHINE;
      if Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet', false) then
        result := reg.ReadString('')
    end;
    reg.RootKey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('\SOFTWARE\Clients\StartMenuInternet\' + result, false) then
      result := reg.ReadString('');
  finally
    reg.Free;
  end;
end;

测试一下：

procedure TForm1.Button1Click(Sender: TObject);
var
  sl: TStringList;
  i: Integer;
  DefBrw: string;
begin
  DefBrw := GetDefaultBrowser;
  sl := TStringList.Create;
  try
    ListRegisteredBrowsers(sl);
    Memo1.Lines.BeginUpdate;
    for i := 0 to sl.Count - 1 do
      if SameText(sl[i], DefBrw) then
        Memo1.Lines.Add(sl[i] + ' (Default)')
      else
        Memo1.Lines.Add(sl[i]);
    Memo1.Lines.EndUpdate;
  finally
    sl.Free;
  end;
end;

Answer 2

该方法查找所有注册为开始菜单 Internet 应用程序的浏览器。实际上，这已经足够了，因为所有主要浏览器都以这种方式注册自己。如果浏览器未能将自己注册为开始菜单 Internet 应用程序，那么它就没有机会让 Windows 注意到它并将该浏览器提供给用户。

解释这一切的 MSDN 主题在这里：http://msdn.microsoft.com/en-us/library/windows/desktop/dd203067.aspx

Windows XP 和 Windows Vista 中的“开始”菜单包含为默认 Internet（浏览器）和电子邮件（邮件）客户端保留的插槽，通常称为“开始菜单 Internet 应用程序”。注册为开始菜单 Internet 应用程序的应用程序会在整个系统（每台机器）上执行此操作。在 Windows Vista 中，用户可以使用默认程序功能来设置每个用户的默认值。