指针和 PROGMEM 的问题

Question

我在 Arduino UNO 上编程，遇到了一个非常烦人的路障。

我对 PROGMEM 有一个非常奇怪的问题，我已将其范围缩小为指针数组的问题。

当我用变量 j 索引 PROGMEM 数组时。它会根据天气返回不同的结果，变量 j 是由静态数字设置还是由另一个变量设置。

程序编号是存储在对象中的整数，并且仅按如下方式设置，内存被分配，变量保持其值。我已经测试过了。

*(this->program) = 0;

将 j 设置为 0 直接产生正确的地址

uint16_t j = 0;
Serial.println(j);    
//printed 0 as expected

address = (uint16_t)*(pgmStringTable + (uint16_t)j); 
Serial.println(address);   
//gave address = 105, which is correct and PROGMEM reads the correct bytes

但是，如下使用 progam 变量设置 j 会产生不正确的地址

uint16_t j = *(this->program);
Serial.println(j);    
//printed 0 as expected

address = (uint16_t)*(pgmStringTable + (uint16_t)j); 
Serial.println(address);   
//gave address = 4, which isnt right and results in PROGMEM read errors

即使试图解决这个集合问题，比如对 *(this->program) 进行一些算术运算或将其发送到返回相同值的整数的函数也无济于事。唯一有效的是循环遍历所有整数，如下所示：

//loops through most unsigned integer values
for(uint16_t j = 0; j < 65000; j++){
  if(j == *(this->program)){
     address = (uint16_t)*(pgmStringTable + (uint16_t)j); 
     //address is correct and PROGMEM works correctly
  }
}

上述工作是确认 malloc 工作正常的更多理由，因为 *(this->program) 在与 j 比较时返回正确的值。

这是一个非常糟糕的解决方法，因为它的效率非常低，并且会在我的程序中浪费大量时间，而这对时间非常敏感。

任何指向解决方案的指针或指针表现得有趣的原因都会非常有用。

问题来自一个非常大的项目，因此为了帮助缩小错误范围，我在一个小得多的 .ino 文件中重新创建了该问题

整个代码是这样的。上传我的 arduino UNO 时产生了同样的错误

编辑：

1. 经过进一步调查，将 j 设置为在我的主项目中不是常量的任何变量（因此该变量不能在项目中的其他任何地方更改）似乎会以与所述相同的方式破坏 PGM。

const char pgmString1[] PROGMEM = "String 1__";
const char pgmString2[] PROGMEM = "2nd String";
const char *const pgmStringTable[] PROGMEM = {pgmString1, pgmString2};




class testObject{

    private:
        uint16_t* program;

    public:


        testObject(){
            program = (uint16_t*) malloc(sizeof(uint16_t));
            *(this->program) = 0;
        }

        void read(){
            if(*(this->program) == 0){
                //the console prints the below, meaning the value is definitly 0
                Serial.println("it was 0");
                *(this->program) = 0;
            }else{
                Serial.println("it wasnt 0");
                
                //if this is uncommeneted, this program outputs the correct values but the above comment will not be dispalyed
                //*(this->program) = 0;
            }

            char temp[10];
            uint16_t j = 0;
            uint16_t address = 0;   

////////////////////////////////////////////// indirectly setting j
            //sets the j value to be 0, which is what is stored in this->program
            j = *(this->program);

            //prints j to make sure its 0, then finds the address of the progmem string
            Serial.print(j);
            Serial.print("  1 Address: |"); 
            address = (uint16_t)*(pgmStringTable + (uint16_t)j);   
            Serial.print(address);     //the address printed is incorrect
            Serial.print("   ");

            //reads byte by byte from the address, it reads the wrong bytes
            for(int i = 0; i < 10; i++){    
                char myChar = pgm_read_byte( address + i );
                Serial.print(myChar);
            }
            Serial.println("\n");
                    
////////////////////////////////////////////// directly setting j
            //but just setting j = 0 works fine
            j=0;

            //so directly setting j as 0, same code as above but it produces the correct output
            //SAME AS ABOVE, COULDNT SEPERATE INTO ITS ONW FUNCTION
            Serial.print(j);
            Serial.print("  2 Address: |");
            address = (uint16_t)*(pgmStringTable + (uint16_t)j);
            Serial.print(address);
            Serial.print("   ");
            for(int i = 0; i < 10; i++){    
                char myChar = pgm_read_byte( address + i );
                Serial.print(myChar);
            }
            Serial.println();
            //

        }
};





testObject pgmReader;

void setup(){
    Serial.begin(9600);
}

void loop(){
    Serial.println("\n\n\n\n\n\n\n\n");
    delay(1000);
    pgmReader.read();

}

Answer 1

不仅pgmString1 和pgmString2 而且pgmStringTable 也是PROGMEM。所以你必须使用pgm_read_函数来读取pgmStringTable。

address = pgm_read_ptr(pgmStringTable + (uint16_t)j);