CMake 中的 Cppcheck 支持

Question

我并不是在询问以某种方式支持 Cppcheck 的各种可用第三方模块。

在 CMake 3.10 中，CMake 似乎获得了一些官方的 Cppcheck 支持。见CMAKE_<LANG>_CPPCHECK。

不幸的是，如何使用这个变量的文档有点稀疏。有没有一个很好的例子来说明 Cppcheck 应该如何与 CMake 3.10（或更高版本）一起使用？

Answer 1

simple example 将是 - 如果您的 PATH 中有 cppcheck 并且您没有指定其他参数 - 通过设置全局 CMAKE_<LANG>_CPPCHECK 变量如下：

cmake_minimum_required(VERSION 3.10)

project(CppCheckTest)

file(
    WRITE "main.cpp"
[=[
int main()
{
    char a[10];
    a[10] = 0;
    return 0;
}
]=] 
)

set(CMAKE_CXX_CPPCHECK "cppcheck")
add_executable(${PROJECT_NAME} "main.cpp")

要扫描的文件会自动添加到cppcheck 命令行。所以上面的例子给出了以下输出（Linux系统上的gcc和cppcheck）：

# make
Scanning dependencies of target CppCheckTest
[ 50%] Building CXX object CMakeFiles/CppCheckTest.dir/main.cpp.o
Checking .../CppCheckTest/main.cpp...
Warning: cppcheck reported diagnostics:
[/mnt/c/temp/*/CppCheckTest/main.cpp:4]: (error) Array 'a[10]' accessed at index 10, which is out of bounds.
[100%] Linking CXX executable CppCheckTest
[100%] Built target CppCheckTest

您可以在现有项目中尝试cppcheck，只需通过cmake 命令行设置CMAKE_CXX_CPPCHECK 变量：

# cmake -DCMAKE_CXX_CPPCHECK:FILEPATH=cppcheck ..

一个更“日常生活”的例子可能会让你在你的CMakeList.txt 中包含类似以下代码 sn-p 的内容：

find_program(CMAKE_CXX_CPPCHECK NAMES cppcheck)
if (CMAKE_CXX_CPPCHECK)
    list(
        APPEND CMAKE_CXX_CPPCHECK 
            "--enable=warning"
            "--inconclusive"
            "--force" 
            "--inline-suppr"
            "--suppressions-list=${CMAKE_SOURCE_DIR}/CppCheckSuppressions.txt"
    )
endif()

参考文献

• CMake Commit: Add properties to run cppcheck along with the compiler

• <LANG>_CPPCHECK target property

  仅当<LANG> 为C 或CXX 时才支持此属性。

  指定一个包含cppcheck 静态分析工具命令行的;-list。 Makefile 生成器和 Ninja 生成器将与编译器一起运行 cppcheck 并报告任何问题。

  如果在创建目标时设置了CMAKE_<LANG>_CPPCHECK 变量的值，则该属性将被初始化。