使用 vb .net 中的复选框发出切换大写锁定

Question

我开发了一个应用程序（使用 vb .net），可以通过单击复选框来切换大写锁定状态。我已经对程序进行了编码，当我单击复选框时，如果选中它，则必须打开大写锁定，如果未选中，则必须关闭它。以下是代码。

Public Class Form1

Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Integer, ByVal dwExtraInfo As Integer)

Private Const VK_CAPITAL As Integer = &H14
Private Const VK_SCROLL As Integer = &H91
Private Const VK_NUMLOCK As Integer = &H90

Private Const KEYEVENTF_EXTENDEDKEY As Integer = &H1
Private Const KEYEVENTF_KEYUP As Integer = &H2

Private Sub checkbutton_caps_CheckedChanged(sender As Object, e As EventArgs) Handles checkbutton_caps.CheckStateChanged

    If checkbutton_caps.Checked = True Then
        Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0)
        checkbutton_caps.Image = Image.FromFile("resources\btn_ico_caps_on.png")

    ElseIf checkbutton_caps.Checked = False Then
        Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0)
        checkbutton_caps.Image = Image.FromFile("resources\btn_ico_caps_off.png")

    End If
End Sub
End Class

现在的问题是它没有按预期工作。如果我选中复选框，则只有复选框的图像会更改，而大写锁定状态不会更改。只有当我单击复选框两次时，大写锁定状态才会更改。所以我需要点击复选框两次来切换大写锁定。我怀疑我使用条件语句的方式有问题。

Answer 1

问题不在于条件逻辑本身（换句话说，您已经正确编写了If 语句），而在于您使用keybd_event 函数的方式。

想想键盘上的物理键。当你“按下”一个键时，实际上会发生两件事：键下降，然后键恢复。在这两件事发生后，按键事件被注册为已经发生。

因此，使用keybd_event 函数触发按键的正确方法是注入一个按键事件，然后是一个按键事件。所以你实际上需要一对调用：

 Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0)
 Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0)

既然您理解了这一点，请回头看看您的代码。复选框控件开始时未选中。第一次单击它时，它会自动检查并触发您的 CheckedChanged 事件处理程序。作为响应，您第一次调用keybd_event，这实际上是“按下”大写锁定键。直到 second 您单击复选框控件，将其 back 切换为未选中状态并将 second 调用到 keybd_event，您实际上触发完全按下大写锁定键。

这样写代码：

Private Sub checkbutton_caps_CheckedChanged(sender As Object, e As EventArgs) Handles checkbutton_caps.CheckStateChanged

    If checkbutton_caps.Checked = True Then
        Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0)
        Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0)
        checkbutton_caps.Image = Image.FromFile("resources\btn_ico_caps_on.png")

    ElseIf checkbutton_caps.Checked = False Then
        Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0)
        Call keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0)
        checkbutton_caps.Image = Image.FromFile("resources\btn_ico_caps_off.png")

    End If

End Sub

或者，更好的是，将触发按键的逻辑封装在另一个函数中，减少代码重复：

Private Sub SimulateKeyPress(ByVal bVKCode As Byte, ByVal bScanCode As Byte)
     keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0)
     keybd_event(VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0)
End Sub

Private Sub checkbutton_caps_CheckedChanged(sender As Object, e As EventArgs) Handles checkbutton_caps.CheckStateChanged

    If checkbutton_caps.Checked = True Then
        SimulateKeyPress(VK_CAPITAL, &H45)
        checkbutton_caps.Image = Image.FromFile("resources\btn_ico_caps_on.png")

    ElseIf checkbutton_caps.Checked = False Then
        SimulateKeyPress(VK_CAPITAL, &H45)
        checkbutton_caps.Image = Image.FromFile("resources\btn_ico_caps_off.png")

    End If

End Sub

甚至更好，使用SendInput function 代替已弃用的keybd_event 函数。除其他外，这使您可以检查和处理错误。

请注意，在 VB.NET 中您确实不需要 Call 语法。那是旧的 VB 6 东西，而不是在 VB.NET 中编写代码的惯用方式。