电子邮件签名 - Word 的 VBscript，带表格

Question

我正在尝试设置公司签名，然后使用 GPO 实现它。

这是我想要完成的：

John Hancock | Paralegal | Company, PC
<Logo (to the left of text)> 60 Test Street | PO Box 1389 | Testing, PA 19820 
Phone: 555.555.5555| Fax: 555.555.5555 | Email: testing@testing.com (need this hyperlinked)

编辑：来自 cmets 的其他信息。

我正在尝试为表格第二行中每个特定行中的文本设置不同的属性（字体大小、字体类型、粗体等）。例如：测试文本（这是粗体和 Calibri） - 测试文本 2（这不是粗体和 Arial）。当我按原样运行脚本时，我会在左侧的第一列中获得徽标，在徽标右侧的第二列中获得一行文本。我不知道如何在右侧，直接在第一行下方添加另一行文本，并让该行文本显示具有不同的字体属性等。

这是我目前的代码：

Set objSysInfo = CreateObject("ADSystemInfo")

Set WshShell = CreateObject("WScript.Shell")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strFirst = objUser.FirstName
strLast = objUser.LastName
strInitials = objUser.Initials
strOffice = objUser.physicalDeliveryOfficeName
strPOBox = objUser.postOfficeBox
strTitle = objUser.Description
strCred = objUser.info
strStreet = objUser.StreetAddress
strLocation = objUser.l
strPostCode = objUser.PostalCode
strPhone = objUser.TelephoneNumber
strMobile = objUser.Mobile
strFax = objUser.FacsimileTelephoneNumber
strEmail = objUser.mail
strCompany = objUser.Company


Const NUMBER_OF_ROWS = 1
Const NUMBER_OF_COLUMNS = 2

Set objWord = CreateObject("Word.Application")
Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature

Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

Set objRange = objDoc.Range()
objDoc.Tables.Add objRange, NUMBER_OF_ROWS, NUMBER_OF_COLUMNS
Set objTable = objDoc.Tables(1)

Set objShape = objTable.Cell(1, 1).Range.Hyperlinks.Add(objSelection.InlineShapes.AddPicture("\\eg-fileserver\admin space\signature\logo.jpg"), "http://www.eastburngray.com",,,"")
objTable.Columns(1).Width = 20
objTable.Columns(2).Width = 320
objTable.Cell(1, 2).Range.Font.Bold = True
objTable.Cell(1, 2).Range.Font.Name = "Calibri"
objTable.Cell(1, 2).Range.Font.Size = 10
objTable.Range.ParagraphFormat.SpaceAfter = 0
objTable.Cell(1, 2).Range.Text = strFirst & strInitials & strLast & " | " & strOffice & " | " & strCompany

Set objSelection = objDoc.Range()

objSignatureEntries.Add "Full Signature", objSelection
objSignatureObject.NewMessageSignature = "Full Signature"

objDoc.Saved = True
objWord.Quit

Answer 1

在 Word 中添加具有各种格式的文本的关键是使用 Range 对象。您可以将 Range 视为不可见的 Selection，主要区别在于您可以拥有任意数量的 Range 对象 - 只能有一个 Selection。更改格式的技巧是“折叠”范围（将其想象为将向右或向左箭头键按到闪烁的“点”，然后继续输入）。

编辑说明：根据 bibadia 的推测，这实际上是关于 VBScript 而不是 VBA 我已经更改了您问题中的标签并正在编辑我的答案以适合 VBScript。 VBScript 不能使用 Word 特定的对象声明和枚举，因此我删除了“Dim As”并将所有 wdEnum 替换为 Integer 等效项。

以您的代码为起点，该方法可能如下所示：

Dim rngCell 
Set rngCell = objTable.Cell(1,2).Range
rngCell.ParagraphFormat.SpaceAfter = 0
rngCell.Text = strFirst & strInitials & strLast & " | " & _
               strOffice & " | " & strCompany & vbCr
rngCell.Font.Bold = True
rngCell.Font.Name = "Calibri"
rngCell.Font.Size = 10
rngCell.Collapse 0  'wdCollapseEnd
rngCell.MoveEnd 1, -1  'wdCharacter, -1
rngCell.Text = strPhone & " | " & strFax & " | " & strEmail
rngCell.Font.Bold = False
rngCell.Font.Size = 8

注意 1：您执行操作的顺序通常与以用户身份输入时相反：首先填充 Range，然后应用格式。

注意 2：在单元格末尾折叠时，Word 会将 Range 位置移动到下一个单元格的开头。因此，代码将点向后移动一个字符，将其放在前一个（原始）单元格的末尾：rngCell.MoveEnd wdCharacter, -1

注意 3：我在第一个 rngCell.Text 的末尾添加了一个 vbCr 以在表格单元格中创建新段落。