使用 Midje 伪造朋友凭证功能

Question

我正在尝试使用 Midje 单独测试我的路由。对于一些命中数据库的路由，我可以使用(provided ...) 将路由与真正的数据库调用隔离开来。我已经介绍了 Friend 进行身份验证，但我无法伪造对凭据函数的调用。

我的凭证函数看起来像这样（它是这样实现的，因为我不希望它被调用）：

(defn cred-fn
  [creds]
  (println (str "hey look I got called with " creds))
  (throw (Exception.)))

路由的中间件如下所示：

(def app 
  (-> app-routes
      (wrap-json-body {:keywords? true :bigdecimals? true})
      wrap-json-response
      (wrap-defaults defaults)
      (friend/authenticate
       {:unauthorized-handler json-auth/login-failed
        :workflows [(json-auth/json-login
                     :login-uri "/login"
                     :login-failure-handler json-auth/login-failed
                     :credential-fn auth/cred-fn)]})
      (ring-session/wrap-session)))

我也尝试过不使用 auth-json-workflow，路由的实现看起来几乎相同，如果有帮助，我可以添加它，但我得到相同的结果。

然后我的测试看起来像这样（使用 ring-mock）：

(defn post [url body]
  (-> (mock/request :post url body)
      (mock/content-type "application/json")
      app))

(fact "login with incorrect username and password returns unauthenticated"
  (:status (post "/login" invalid-auth-account-json)) => 401
  (provided
    (auth/cred-fn anything) => nil))
(fact "login with correct username and password returns success"
  (:status (post "/login" auth-account-json)) => 200
  (provided
    (auth/cred-fn anything) => {:identity "root"}))

然后我得到以下运行测试的输出：

hey look I got called with {:password "admin_password", :username "not-a-user"}
FAIL at (handler.clj:66)
These calls were not made the right number of times:
    (auth/cred-fn anything) [expected at least once, actually never called]
FAIL "routes - authenticated routes - login with incorrect username and password returns unauthenticated" at (handler.clj:64)
    Expected: 401
      Actual: java.lang.Exception
          clojure_api_seed.authentication$cred_fn.invoke(authentication.clj:23)

hey look I got called with {:password "admin_password", :username "root"}
FAIL at (handler.clj:70)
These calls were not made the right number of times:
    (auth/cred-fn anything) [expected at least once, actually never called]

FAIL "routes - authenticated routes - login with correct username and password returns success" at (handler.clj:68)
    Expected: 200
      Actual: java.lang.Exception
          clojure_api_seed.authentication$cred_fn.invoke(authentication.clj:23)

所以从我可以看到提供的声明没有生效，我不知道为什么。有什么想法吗？

Answer 1

我最近遇到了类似的问题，经过一番挖掘，我 我想我明白为什么会这样。让我们看看如何 auth/cred-fn 的绑定随时间而变化。

(clojure.pprint/pprint (macroexpand '(defn cred-fn
                                                [creds]
                                                (println (str "hey look I got called with " creds))
                                                (throw (Exception.)))))
(def
 cred-fn
 (clojure.core/fn
  ([creds]
   (println (str "hey look I got called with " creds))
   (throw (Exception.)))))

正如您在上面看到的，defn 宏在当前命名空间中实习符号 cred-fn 并将其绑定到 Var 引用 你的虚拟函数。

(def app 
    (-> app-routes
        (wrap-json-body {:keywords? true :bigdecimals? true})
        wrap-json-response
        (wrap-defaults defaults)
        (friend/authenticate
        {:unauthorized-handler json-auth/login-failed
        :workflows [(json-auth/json-login
                    :login-uri "/login"
                    :login-failure-handler json-auth/login-failed
                    :credential-fn auth/cred-fn)]})
        (ring-session/wrap-session)))

这是重要的部分。在编译时，我们线程 app-routes 通过一系列功能。这些功能之一 是friend/authenticate，它采用键为:workflows 的映射。 :workflows 的值是一个向量，其结果为 对json-auth/json-login 的调用，接收auth/credential-fn 作为参数。记住，我们在一个 def 里面，所以这就是全部 发生在编译时。我们在中查找符号cred-fn auth 命名空间，并传入符号绑定的 Var 至。在这一点上，这仍然是虚拟实现。 据推测，json-auth/json-login 捕获了这个实现 并设置一个调用它的请求处理程序。

(fact "login with incorrect username and password returns unauthenticated"
    (:status (post "/login" invalid-auth-account-json)) => 401
    (provided
    (auth/cred-fn anything) => nil))

现在我们在运行时。在我们的前提条件下，Midje 重新绑定 符号 auth/cred-fn 到引用模拟的 Var。但是 auth/cred-fn 的值已经被捕获，当我们 def'd app 在编译时。

那么您发布的解决方法是如何起作用的呢？ （这实际上是导致我 尤里卡时刻 - 谢谢。）

(defn another-fn []
  (println (str "hey look I got called"))
  (throw (Exception.)))

(defn cred-fn [creds]
  (another-fn))

在你的测试中......

(fact "login with incorrect username and password returns unauthenticated"
  (:status (post "/login" invalid-auth-account-json)) => 401
  (provided
    (auth/another-fn) => nil))

(fact "login with correct username and password returns success"
  (:status (post "/login" auth-account-json)) => 200
  (provided
    (auth/another-fn) => {:identity "root"}))

这是有效的，因为在编译时，auth/cred-fn 的值 被捕获是一个简单地委托给 auth/another-fn。请注意，auth/another-fn 尚未 评价过。现在在我们的测试中，Midje 重新绑定 auth/another-fn 引用模拟。然后它执行帖子，并在某处 在中间件中，auth/cred-fn 被调用。里面 auth/cred-fn，我们查找绑定到 auth/another-fn 的 Var（其中 是我们的模拟），并调用它。当然，现在的行为是 完全符合您第一次的预期。

这个故事的寓意是，careful with the def in Clojure

Answer 2

我仍然不确定为什么会发生这种情况，但我有一个解决方法。如果我将credential-fn 替换为：

(defn another-fn
  []
  (println (str "hey look I got called"))
  (throw (Exception.)))

(defn cred-fn
  [creds]
  (another-fn))

然后在测试中为新函数创建一个 fake，像这样：

(fact "login with incorrect username and password returns unauthenticated"
  (:status (post "/login" invalid-auth-account-json)) => 401
  (provided
    (auth/another-fn) => nil))

(fact "login with correct username and password returns success"
  (:status (post "/login" auth-account-json)) => 200
  (provided
    (auth/another-fn) => {:identity "root"}))

我得到了我期望的结果。 cred-fn 仍会被调用，但由于provided，another-fn 不会被调用。

如果有人知道为什么会这样，我很想知道。这可能是由于凭证函数被调用的方式？ - https://github.com/marianoguerra/friend-json-workflow/blob/master/src/marianoguerra/friend_json_workflow.clj#L46