以正确的方式进行coldfusion 11循环

Question

我在其中一个页面中看到此代码，看起来很烦人，如果我在 Coldfusion 11 上，它可以被缩短 https://trycf.com/gist/701515844d5e41549a7b6e61dfafeaa0/lucee5?theme=monokai

这是代码的样子

<cfloop list="#mqry.columnList#" index="col">
<cfset ColRow ="#mqry.columnList#," >                     
</cfloop>  


<cfset  x = replace(ColRow,"CONDITION1","CONDITION") & chr(13) & chr(10)>
<cfloop query="mqry">               
<cfloop list="#mqry.columnList#" index="colN"> 
    <cfset f = Replace("#mqry[colN][currentRow]#" ,"""","","All")>
    <cfset f = REReplaceNoCase("#mqry[colN][currentRow]#" , "<[^>]*(?:>|$)", "", "ALL")>
    <cfset x = x & """#_f#"",">  
</cfloop> 
<cfset  x = x & chr(13) & chr(10)>                          
</cfloop>

我认为我可以做到的第一个值：

mquery.columnlist - no need to loop over 

Answer 1

嵌套循环没有任何问题。您遍历所有行，然后使用列名遍历每行的每个单元格。我重写了你的代码以便更容易理解：

<cfset NEWLINE = (chr(13) & chr(10))>
<cfset DELIM   = ",">
<cfset QUOTE   = '"'>

<!--- column headers --->
<cfset x = mqry.columnList>

<!--- replace column names as desired --->
<cfset x = replace(x, "CONDITION1", "CONDITION")>

<!--- next line --->
<cfset x &= NEWLINE>

<cfloop query="mqry">

    <cfset row = []>

    <cfloop list="#mqry.columnList#" index="colN">

        <cfset cellValue = mqry[colN][mqry.currentRow]>

        <!--- remove all quotes --->
        <cfset cellValue = replace(cellValue, QUOTE, "", "ALL")>

        <!--- remove tags --->
        <cfset cellValue = reReplaceNoCase(cellValue, "<[^>]*(?:>|$)", "", "ALL")>

        <!--- prefix with underscore --->
        <cfset cellValue = ("_" & cellValue)>

        <!--- wrap in quotes --->
        <cfset cellValue = (QUOTE & cellValue & QUOTE)>

        <cfset row.add(cellValue)>

    </cfloop>

    <!--- combine cell values into a row --->
    <cfset x &= arrayToList(row, DELIM)>

    <!--- next line --->
    <cfset x &= NEWLINE>

</cfloop>

<cfoutput>#x#</cfoutput>