gnuplot - 如何使 zmin 等于 zmax 在 z 轴上保持自动缩放

Question

如何使在 z 轴上缩放的结果输出在 xy 平面上对称：zmax = zmin，保持 z 轴上的自动缩放打开？ (GNUplot 5.0)

resulting graph - 3d-polar.png

在 GNUplot 中是否有这种可能性，或者只能使用固定范围的 cbrange？

用于极地热图的示例：

reset
set terminal pngcairo size 800,800
set output '3d-polar.png'
set lmargin at screen 0.05
set rmargin at screen 0.85
set bmargin at screen 0.1
set tmargin at screen 0.9

set pm3d map
unset key
set multiplot

set parametric
set grid xtics ytics

set angles degree
set autoscale xfix
set autoscale yfix
set autoscale zfix
set palette model RGB defined ( 0"black", 1"white", 2"grey")
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3
unset multiplot

_FullWV.dat 文件是here。

Answer 1

您可以使用stats 提取第三列的最小值和最大值，并相应地定义 cbrange。

reset
set terminal pngcairo size 800,800
set output '3d-polar.png'
set lmargin at screen 0.05
set rmargin at screen 0.85
set bmargin at screen 0.1
set tmargin at screen 0.9

set pm3d map
unset key
set multiplot

stats '_FullWV.dat' using 3
max(a,b) = (a>b) ? a : b

Z_MAX = max(-STATS_min, STATS_max)

set parametric
set grid xtics ytics

set angles degree
set autoscale xfix
set autoscale yfix
#set zrange [-Z_MAX : Z_MAX]
set cbrange [-Z_MAX : Z_MAX]

set palette model RGB defined ( 0"black", 1"white", 2"grey")
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3
unset multiplot