vbscript查找关键进程

Question

我编写了一个 vbscript 来从服务器中查找关键进程的详细信息。如果该进程存在，我的进程名称很少，那么脚本应该给出提到的输出。但是这里的问题是即使进程存在或不存在脚本给出与 "CriticalProcesses=NA" 相同的输出。任何人都可以帮助解决这个问题吗？非常感谢任何帮助

   strComputer = "."
   Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
   Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Process", "WQL", _
                                          wbemFlagReturnImmediately + wbemFlagForwardOnly)

   For Each objItem In colItems
   'WScript.Echo "Caption: " & objItem.Caption

      Dim process

      Process = objItem.Caption

   Next

   If inStr(process, "SQLserver") Or inStr(process, "mysql") then

      wscript.echo "CriticalProcesses=Database"

   else if inStr(process, "java") Or inStr(process, "weblogic") Then

      wscript.echo "CriticalProcesses=wls"

   else

      wscript.echo "CriticalProcesses=NA"

   End if        
End if 

Answer 1

这里的问题是您在 for 循环中迭代您的进程，然后在循环之外测试进程名称。因此，您的 If instr(process.. 位仅检查从您的 for 循环中找到的 last 进程。

要解决此问题，请将 if 测试粘贴到您的循环中，以便它可以测试找到的每个进程。

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Process", "WQL", _
    wbemFlagReturnImmediately + wbemFlagForwardOnly)

For Each objItem In colItems
    'WScript.Echo "Caption: " & objItem.Caption
    Dim process
    Process = objItem.Caption

    If inStr(process, "SQLserver") Or inStr(process, "mysql") Then
        wscript.echo "CriticalProcesses=Database"
    ElseIF inStr(process, "java") Or inStr(process, "weblogic") Then
        wscript.echo "CriticalProcesses=wls"
    Else
        'wscript.echo "CriticalProcesses=NA"
    End If
Next

我还将您的Else If 更改为ElseIf 并删除了不必要的第二个End If。

最后，我在您的Else 中注释掉了那个回显，因为您可能不希望脚本一遍又一遍地指向Echo NA。至少...我不会按 Enter 键 200 次。

---

要捕获wls 或database 类型的进程是否正在运行，然后在最后只回显一次，您可以在布尔变量中捕获每种类型的真/假，然后在之后进行测试 em> for 循环：

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Process", "WQL", _
    wbemFlagReturnImmediately + wbemFlagForwardOnly)

Dim hasDBProcess
Dim hasWLSProcess

hasDBProcess = False
hasWLSProcess = False

For Each objItem In colItems
    'WScript.Echo "Caption: " & objItem.Caption
    Dim process
    Process = objItem.Caption

    If inStr(process, "SQLserver") Or inStr(process, "mysql") Then
        hasDBProcess = True
    ElseIF inStr(process, "java") Or inStr(process, "weblogic") Then
        hasWLSProcess = True
    End If
Next

If hasDBProcess Then 
    wscript.echo "CriticalProcess=Database"
ElseIf hasWLSProcess Then
    wscript.echo "CriticalProcess=wls"
Else
    wscript.echo "CriticalProcess=NA"
End if