Excel VBA：删除 Sheet1 时出现运行时错误 1004

Question

我仍在努力学习 VBA，所以这可能是一个愚蠢的问题，但我希望循环浏览大约 90-95 张的工作簿，将每个工作簿分成自己的工作簿，并将其保存为原始文件中工作表的名称。

脚本有效，但前提是我注释掉 .Worksheets(1).Delete，我想知道为什么...它在我运行它的两个工作表上都抛出 1004 错误，但不是同一个地方。第一张在标签 4 上出错，第二张在标签 40 左右。

现在我已将 FileNamePrefix 变量设置为切换，因为我在“ThisWorkbook”下的 VBA 窗口中运行它，因为我还没有弄清楚如何从它自己的工作表中运行这个宏，并且根据映射到的文件的名称/扩展名选择前缀。 （AC 以 .xlsm 形式出现，CC 以 .xlsx 形式出现）这仍在我的待办事项中，所以请不要剧透！ :)

宏：

Sub Sheet_SaveAs()
    Dim wb As Workbook
    Dim WS_Count As Integer
    Dim ActiveSheetName As String
    Dim ws As Worksheet
    Dim FileNamePrefix As String
    Dim FileName As String
    Dim FilePath As String
    'FileNamePrefix = "CC Dashboard "
    FileNamePrefix = "AC Dashboard "
    WS_Count = ActiveWorkbook.Worksheets.Count
    MsgBox (" This will create: " & WS_Count & " Files")
    For Each ws In ThisWorkbook.Worksheets
        Set wb = Workbooks.Add(xlWBATWorksheet)
        With wb
            ThisWorkbook.Worksheets(ws.Name).Copy After:=.Worksheets(.Worksheets.Count)
            Application.DisplayAlerts = False
            .Worksheets(1).Delete
            Application.DisplayAlerts = True
            .SaveAs ThisWorkbook.Path & "\" & FileNamePrefix & ws.Name
            .Close False
        End With
        ws.Name = FileNamePrefix & ws.Name
    Next
    MsgBox (" Done! ")
End Sub

Answer 1

因此，让我们摆脱删除，只使用您想要的工作表创建新文件。我还对您的代码做了一些清理工作。

Sub Sheet_SaveAs()
    Dim wb As Workbook
    Dim WS_Count As Integer
    Dim ActiveSheetName, FileNamePrefix, FileName, FilePath As String
    Dim ws As Worksheet

    'FileNamePrefix = "CC Dashboard "
    FileNamePrefix = "AC Dashboard "
    WS_Count = ActiveWorkbook.Worksheets.Count
    MsgBox (" This will create: " & WS_Count & " Files")
    For Each ws In ThisWorkbook.Worksheets
        ws.Copy 'this creates a new file with only the one sheet, so no Delete needed
        ActiveWorkbook.SaveAs ThisWorkbook.Path & "\" & FileNamePrefix & ws.Name
        ActiveWorkbook.Close False
    Next
    MsgBox (" Done! ")
End Sub