无法在“require”加载的@INC Perl perl 文件中找到

Question

我有一个简单的 Perl 脚本，它使用位于另一个文件 common.pl 中的辅助函数：

main.pl

#!/usr/bin/perl

use strict;
use warnings;

use Cwd 'abs_path';

use File::Basename qw( fileparse );
use File::Path qw( make_path );
use File::Spec;


require "common.pl";  # line 15

#...

common.pl

#!/usr/bin/perl

use strict;
use warnings;

sub getTimeLoggerHelper{
  #....
}

1;

本地一切运行良好，但是当我尝试通过 ssh 运行它时出现错误：

Can't locate common.pl in @INC  (@INC contains: 
/Library/Perl/5.18/darwin-thread-multi-2level  /Library/Perl/5.18 
/Network/Library/Perl/5.18/darwin-thread-multi-2level
/Network/Library/Perl/5.18
/Library/Perl/Updates/5.18.2/darwin-thread-multi-2level
/Library/Perl/Updates/5.18.2
/System/Library/Perl/5.18/darwin-thread-multi-2level
/System/Library/Perl/5.18 
/System/Library/Perl/Extras/5.18/darwin-thread-multi-2level
/System/Library/Perl/Extras/5.18 .) at /Users/snaggs/scripts/main.pl line 15.

[编辑 1]

如果我登录到远程计算机并运行相同的脚本，则不会出现错误。

[编辑 2]

我还尝试将common.pl 转换为模块：

common.pm

package Common;

use strict;
use warnings;

sub getTimeLoggerHelper{
  #....
}

1;
__END__

从main.pl 我这样称呼它

use Module::Load;
load Common;

同样的问题，本地工作，来自 ssh - 同样的错误：

Can't locate Common.pm in @INC (you may need to install the Common module)

如何解决这个问题？

Answer 1

如果您需要为此使用require，请提供完整路径

require "/full/path/to/common.pl";

这在ssh 上是必需的，即使文件与脚本位于同一目录中，因为在ssh 上@INC 中的. 是不是脚本的目录（因为工作目录. 可能是您的$HOME）。在其他情况下也会发生这种情况。^†

请注意，这样您将导入common.pl 中的所有内容。

改用合适的模块有很多好处。然后文件是.pm，按照惯例，文件名大写（和帕斯卡大小写）。

这是一个简单的示例，包含文件 bin/main.pl 和 lib/Common.pm

bin/main.pl

use warnings;
use strict;

use FindBin 1.51 qw($RealBin);  # Directory in which the script is
use lib "$RealBin/../lib";      # Where modules are, relative to $RealBin

use Common qw(test_me);

test_me();

设置@INC 的关键部分，在其中查找模块， 使用lib pragma 完成。它在编译时将目录添加到默认@INC 的开头。 FindBin 的$RealBin 是脚本的目录，链接已解析。我们使用它以便添加的路径是相对于脚本的，而不是硬编码的。当脚本及其库结合在一起时，这有助于源组织。

另一种设置方法是通过environment variable PERL5LIB。与bash

export PERL5LIB=/path/to/libdir

然后，对于Module.pm 中的libdir，您只需说出use Module 即可找到它。这对于位于特定位置的模块很有用，供各种脚本使用。

lib/Common.pm

package Common;

use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw( test_me );

sub test_me { print "Hello from ", __PACKAGE__, "\n" }

1;

当一个包是used 时，它的文件首先是required，然后在编译时运行模块的import 方法。调用者实际上是通过import 获取模块中定义的符号（函数和变量的名称），我们必须在模块中提供import 方法（或使用完全限定名称Module::function，在来电者）。

use Exporter 的行引入了 its import 例程，因此我们不必自己编写。对于旧版本的Exporter，这是通过继承使用的，通常是@ISA = ('Exporter')。请参阅文档。

然后通过@EXPORT_OK 提供符号。这需要调用者列出要使用的函数；默认情况下，它不会将任何内容“推送”到它们的命名空间中。还有 %EXPORT_TAG 很有帮助，特别是当调用者导入的符号列表变长时。

---

^† 这实际上只是将当前working directory (.) 用于脚本目录的一般问题的一个示例：它不是；一般来说，它不是。

还有一点需要注意，从 5.26 版开始，出于安全原因，@INC 中的 .（当前目录）is not anymore。这也可能被向后移植到早期版本。

所以只需使用$RealBin，如图所示（1.51 版有一个重要的修复）。