BeforeSend 传递给 Backbone 的 Fetch，不允许触发事件

Question

我有一个 Backbone 集合。我正在使用 fetch 在初始化时将 Facebook 帖子延迟加载到模型中。

https://gist.github.com/2271437

exports.Collection = class Posts extends Backbone.Collection
  initialize: (models, options) =>
    @id = options.id
    @activeDetails = false
    @on "loadDetails", @loadDetails
    @on "detailsLoaded", @logger
    debug "initialized posts"
    @fetch
      beforeSend: () =>
        console.log "about to fetch..."
        @trigger "postsLoading"
      success: (collection, response) => 
        debug "successfully loaded ajax"
        @trigger "postsLoaded"
      error: (collection, response) => @trigger "postsLoadingError"

由于某种奇怪的原因，当我尝试使用 beforeSend 处理程序触发事件时，事件不会触发。我可以调用任何函数，但如果任何函数尝试使用@trigger "eventName"，则事件永远不会以我能够观察到的方式触发。在上面的示例中，console.log 函数工作正常，但触发失败。

有什么想法吗？成功和错误处理程序的工作非常出色。

Answer 1

您在initialize 方法中调用fetch，因此在触发事件之前没有任何机会绑定到该集合。 initialize 方法是在创建集合实例时调用的，这意味着您在构造函数返回之前调用了fetch，但是您需要一个集合实例才能绑定到它的事件。

考虑一些看起来更像这样的东西：

class Posts extends Backbone.Collection
  do_things: ->
    @fetch
      beforeSend: () =>
        console.log "about to fetch..."
        @trigger "postsLoading"
      success: (collection, response) => 
        debug "successfully loaded ajax"
        @trigger "postsLoaded"
      error: (collection, response) => @trigger "postsLoadingError"

如果你这样做：

p = new Posts
p.on('postsLoading', -> console.log('loading'))     
p.do_things()

你会看到你的postsLoading事件确实被触发了。

演示：http://jsfiddle.net/ambiguous/PDeFg/

故事的寓意很简单：

如果您关心事件侦听器，请不要在构造函数中调用 fetch。