为什么使用 CoffeeScript 类继承时 Backbone 模型不能正常工作

Question

我看过几篇关于如何将 CoffeeScript 的扩展功能与 Backbone 一起使用的帖子，但我无法让它工作。以下代码：

Backbone = require 'Backbone'

# The backbone way
Base = Backbone.Model.extend (
    initialize: ->
)

Model  = Base.extend (

    initialize: ->
        console.log 'initialize called'
        @on 'change:foo', ->
            console.log 'foo changed (Base)'

    defaults: (
        foo: 'bar'
    )
)

model = new Model()
model.set 'foo', 'baz'
console.log model.get 'foo'



# The coffeescript way with double ineritance
class Base2 extends Backbone.Model
    constructor: ->

class Model2 extends Base2

    constructor: ->
        console.log 'constructor called (Base2)'
        @on 'change:foo', ->
            console.log 'foo changed (Base2)'

    defaults: (
        foo: 'bar'
    )

model2 = new Model2 (foo: 'bar')

model2.set 'foo', 'baz2'
console.log model2.get 'foo'

投掷：

  % coffee index.coffee                                                                                                                                                                            
initialize called
foo changed (Base)
baz
constructor called (Base2)
TypeError: Cannot read property 'foo' of undefined
  at Model2._.extend.set 

你也可以在这里玩http://codepen.io/guyht/pen/LEOdZr?editors=001

Answer 1

您的问题是您通过指定自己的constructor 来替换Backbone 的构造函数。 Backbone 需要使用自己的构造函数来设置所有 Backbone 内部结构，你的类构造函数代码应该在 initialize 中，就像你使用 Backbone 的 extend 函数而不是 CoffeeScript 的 extends 关键字时一样：

class Base2 extends Backbone.Model
    initialize: ->

class Model2 extends Base2

    initialize: ->
        console.log 'initialize called (Base2)'
        @on 'change:foo', ->
            console.log 'foo changed (Base2)'

    defaults: (
        foo: 'bar'
    )

更新的演示：http://codepen.io/anon/pen/myqxWY