根据日期和条件返回数组

【问题标题】：Return Array based on Dates and Criteria根据日期和条件返回数组
【发布时间】：2019-07-19 08:21:33
【问题描述】：

我正在使用 Google 表单创建费用和收入表。我的家人将能够使用一个简单的表格来跟踪他们的购买和收入，但在后端，我想更好地组织数据。

我需要我的工作表来读取原始数据、查找特定日期之间的数据并返回这些项目的数组。问题是我可以查找并返回所有内容，但我只想返回特定的列。（我想有单独的费用和收入列）

我尝试使用过滤器功能，该功能可用于查找特定日期之间的项目，但它会返回工作表中的所有数据。

=FILTER('Form Raw Data'!A3:M6, 'Form Raw Data'!C3:C6 >=C1, 'Form Raw Data'!C3:C6 <=D1)

在理想情况下，公式将仅返回标记为费用或收入的项目数组。即使我只能获得显示这 2 个类别的行，我也可以隐藏多余的列。

【问题讨论】：

标签： regex filter google-sheets google-sheets-formula google-sheets-query

【解决方案1】：

单元格A9：

=QUERY('Form Raw Data'!A3:M, "select B,C,G,H where D = 'Expense'", 0)

单元格G9：

=QUERY('Form Raw Data'!A3:M, "select B,C,F,H where D = 'Income'", 0)

日期范围A9：

=QUERY('Form Raw Data'!A3:M, 
 "select B,C,G,H 
  where D = 'Expense' 
    and C >= date '"&TEXT(C1, "yyyy-mm-dd")&"' 
    and C <= date '"&TEXT(D1, "yyyy-mm-dd")&"'", 0)

日期范围G9：

=QUERY('Form Raw Data'!A3:M, 
 "select B,C,F,H 
  where D = 'Income' 
    and C >= date '"&TEXT(C1, "yyyy-mm-dd")&"' 
    and C <= date '"&TEXT(D1, "yyyy-mm-dd")&"'", 0)

【讨论】：

当然可以！ docs.google.com/spreadsheets/d/…
FREAKING AWESOME....从来没有想过尝试查询...非常感谢！
我现在将努力添加过滤器，以便它只查找范围之间的日期......原始数据将是一个包含 1000 行事务的运行表，但我会制作代表所有月份的多张纸……如果有意义的话