为什么我的自动过滤器用于删除带零的行后会删除标题？

Question

我正在尝试删除费用为 0 的费用报告中的行，因为该信息并不重要。我正在使用自动过滤器来过滤数量列中只有零的行，并删除这些行。问题是当代码在这个任务之后继续下一步时，它使我的报表文档没有以前的标题，而这些标题非常重要。

我尝试将范围从“AB1:AB”更改为“AB2:AB”，但什么也没做，在第二个连接范围值中，我尝试将“AB”更改为“AB2”，但返回错误声明对象'_global'的“方法'范围'失败。”

Application.ScreenUpdating = False
        Range("AB1:AB" & Range("AB" & Rows.Count).End(3)(1).Row).AutoFilter 1, 0#, xlAnd, 0
            Range("AB2:AB" & Range("AB" & Rows.Count).End(3)(1).Row).SpecialCells(12).EntireRow.Delete
        ActiveSheet.AutoFilterMode = False
    Application.ScreenUpdating = True

Answer 1

您遇到的问题是，如果 AB 列中没有 0，您现有的代码将过滤为仅显示标题行，然后将其删除。我添加了一些代码来循环遍历 AB 列，并在执行现有代码之前检查是否存在任何 0。

我正在编辑这个答案，它不再使用您的 AutoFilter 方法。下面的代码应该可以实现您想要实现的目标，并且它可以避免在循环中删除行的潜在问题，如 cmets 中突出显示的那样。

我已再次编辑以更正您使用包含 0（例如 10.05）的代码删除值描述的问题。

Sub Delete_Zero_Rows()

Dim Firstrow As Long
Dim Lastrow As Long
Dim Lrow As Long

With Worksheets("Sheet1")

    'Set the first and last row to loop through
    Firstrow = .UsedRange.Cells(1).Row
    Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row

    'Loops from Lastrow to Firstrow (bottom to top)
    For Lrow = Lastrow To Firstrow Step -1

        'Checks the values in column AB
        With .Cells(Lrow, "AB")

            If Not IsError(.Value) Then

                If .Value = "0" Then .EntireRow.Delete

            End If
        End With
      Next Lrow
    End With
End Sub

请记住将我的代码中的“Sheet1”替换为您调用的工作表。

这应该可以解决您的问题！