将过滤后的表格数据传递给 ListBox

Question

我有一张下表：

我正在尝试过滤数据，然后将过滤后的数据显示到用户窗体上的列表框。 到目前为止的代码：

Dim iList As Variant

Sheet1.ListObjects("PostOneTable").Range.AutoFilter Field:=1, Criteria1:=TextBox1.Value & "*"
Sheet1.ListObjects("PostOneTable").Range.AutoFilter Field:=2, Criteria1:=TextBox2.Value & "*"
Sheet1.ListObjects("PostOneTable").Range.AutoFilter Field:=3, Criteria1:=TextBox3.Value & "*"
Sheet1.ListObjects("PostOneTable").Range.AutoFilter Field:=5, Criteria1:=TextBox4.Value & "*"

Dim jList As Range

Set jList = 
Sheet1.ListObjects("PostOneTable").DataBodyRange.SpecialCells(xlCellTypeVisible)

ListBox1.List = jList

但是，在运行代码时，我遇到了一些问题。 首先，过滤器似乎没有正确应用。比如我用一个字符串，比如：

Sheet1.ListObjects("PostOneTable").Range.AutoFilter Field:=1, Criteria1:="ryd"

我希望只能在表格和列表框中看到第四项。但是，两者都是空白。

第二个问题是代码没有将过滤后的列表驱动到文本框。

请注意，我知道使用循环的其他搜索方式。然而，这种方法 很好，因为最终用户将能够直接在表格中看到他们在表单上的操作结果。

谢谢！

编辑： 在玩它时，我发现了一些有趣的东西。如果我注释掉驱动数据到列表框的部分并重写过滤行，过滤现在可以工作了。

Answer 1

Range.Value 仅返回范围内第一个区域的值。 Range.SpecialCells(xlCellTypeVisible) 将返回一个 Range，其中包含每个连续单元格块的区域。

ListBox1.List = jList

ListBox1.List 将只有第一组可见行的数据（第一组在jList 中）。

您仍然可以使用ListObject 过滤数据。您只需要编写一个函数来返回可见数据。这是一项琐碎的任务。

ListBox1.List = ListObjectVisibleData(Sheet1.ListObjects("PostOneTable"))

Public Function ListObjectVisibleData(ByVal ListObject As ListObject)
    Dim Map As New Collection
    Dim Row As Range
    For Each Row In ListObject.DataBodyRange.Rows
        If Not Row.EntireRow.Hidden Then
            Map.Add Row
        End If
    Next
    
    Dim Results As Variant
    Dim r As Long, c As Long
    
    If Map.Count = 0 Then
        ReDim Results(1 To 1, 1 To ListObject.ListColumns.Count)
    Else
        ReDim Results(1 To Map.Count, 1 To ListObject.ListColumns.Count)
        For Each Row In Map
            r = r + 1
            For c = 1 To UBound(Results, 2)
                Results(r, c) = Row.Cells(1, c).Value
            Next
        Next
    End If
    
    ListObjectVisibleData = Results
End Function