不明白交互在 Spock 中是如何工作的

Question

这是一个在 Groovy 中超级简单的 spock 测试用例。！！本规范文件中定义的所有类/接口。 （spock 中的规范文件只是一个测试用例文件）。

似乎无法理解工作流程。在测试用例工作流程中，模拟对象是如何被实例化、注入和销毁的？任何帮助表示赞赏...

我遇到的特殊问题是理解交互语句：1*mockURLAdapter.openConnection() 的工作原理。在我的理解中，这只是一个验证语句，断言使用非空参数调用方法“openConnection(_)”。调用此断言如何/为什么会导致方法 weatherService.run() 失败？返回的异常见代码...

import spock.lang.Specification

class WeatherServiceImpl {
    private URLAdapter urlAdapter;
    private URLConnection urlConn;

    public WeatherServiceImpl(urlAdapter){
        this.urlAdapter=urlAdapter
    }

    def run(city) {
        urlConn=urlAdapter.openConnection(city)
        return urlConn.getResponseCode()

    }

}

interface URLAdapter {
    def openConnection(city)

}


class WeatherServiceImplSpec extends Specification {

    def mockURLAdapter = Mock(URLAdapter)
    def mockURLConn    = Mock(HttpURLConnection)
    def weatherService=new WeatherServiceImpl(mockURLAdapter);


    def "Need to figure out the effects of lines: 'troublesome' and 'weirdo' "() {
        given:
        mockURLConn.getResponseCode()>> 9999
        mockURLAdapter.openConnection(_)>>mockURLConn;

        when:
        def result=weatherService.run("New York")

        then:
        // Uncommenting line 'troublesome' below throws a null-pointer exception:
        // java.lang.NullPointerException: Cannot invoke method getResponseCode() on null object
        //      at WeatherServiceImpl.run(URLAdapterConnectionSpec.groovy:29)
        //      at WeatherServiceImplSpec.delivers events to all subscribers(URLAdapterConnectionSpec.groovy:54)

        // Commenting out line 'troublesome' gives no issue!!

        // Line 'troublesome':
        // 1*mockURLAdapter.openConnection(_)

        // Line 'weirdo':
        // And yet, line 'weirdo' works just fine, commented or not!(i.e. test passes, no exception thrown)!!
        1*mockURLAdapter.openConnection(_)>>mockURLConn;

        //WTH is happening! ?
        result==9999


    }

}

Answer 1

你指定了两次 mockURLAdapter 应该返回的内容，第二次你说不返回任何东西，当然这取决于你最后的决定。

// Line 'troublesome':
1 * mockURLAdapter.openConnection(_)

这意味着当调用 openConnection(_) 时不会返回任何内容。如果你想指定交互，那么你应该把它放在 then: 子句中

正确的做法应该是这样的：

def "Need to figure out the effects of lines: 'troublesome' and 'weirdo' "() {
        when:
        def result=weatherService.run("New York")

        then:
        1 * mockURLAdapter.openConnection(_) >> mockURLConn;
        1 * mockURLConn.getResponseCode() >> 9999

        result == 9999
}