MacOS 程序集的 64 位系统调用文档

Question

我很难找到在 MacOS 上编写 64 位程序集的好文档。

64-bit SysV ABI 在 A.2.1 节中说了以下内容，this SO post 引用了它：

• 系统调用是通过 syscall 指令完成的。内核破坏 注册 %rcx 和 %r11。

• 从系统调用返回，寄存器 %rax 包含 系统调用。 -4095 和 -1 之间的值表示错误， 它是-errno。

这两句话在 Linux 上是可以的，但在 macOS Sierra 上是错误的，代码如下：

global _start
extern _exit

section .text
_start:

; Align stack to 16 bytes for libc
and rsp, 0xFFFFFFFFFFFFFFF0

; Call write
mov rdx, 12             ; size
mov rsi, hello          ; buf
mov edi, 1              ; fd
mov rax, 0x2000004      ; write ; replace to mov rax, 0x1 on linux
syscall

jc .err                 ; Jumps on error on macOS, but why?
jnc .ok

.err:
mov rdi, -1
call _exit              ; exit(-1)

.ok:
; Expect rdx to be 12, but it isn't on macOS!
mov rdi, rdx
call _exit              ; exit(rdx)

; String for write
section .data
hello:
.str db `Hello world\n`
.len equ $-hello.str

使用 NASM 编译：

; MacOS: nasm -f macho64 syscall.asm && ld syscall.o -lc -macosx_version_min 10.12 -e _start -o syscall
; Linux: nasm -f elf64 syscall.asm -o syscall.o && ld syscall.o -lc -dynamic-linker /lib64/ld-linux-x86-64.so.2 -o syscall

在 macOS 上运行：

./syscall      # Return value 0
./syscall >&-  # Return value 255 (-1)

我发现：

• 系统调用返回errno 并设置错误时的进位标志，而不是在rax 中返回-errno
• rdx 寄存器被 syscall 破坏
• 在 Linux 上，一切正常

为什么rdx 被破坏了？为什么系统调用不返回-errno？我在哪里可以找到真正的文档？

我发现有人谈论系统调用错误的进位标志的唯一地方是here

Answer 1

我用过这个：

# as hello.asm -o hello.o
# ld hello.o -macosx_version_min 10.13 -e _main -o hello  -lSystem
.section __DATA,__data
str:
  .asciz "Hello world!\n"

.section __TEXT,__text
.globl _main
_main:
  movl $0x2000004, %eax           # preparing system call 4
  movl $1, %edi                   # STDOUT file descriptor is 1
  movq str@GOTPCREL(%rip), %rsi   # The value to print
  movq $13, %rdx                  # the size of the value to print
  syscall

  movl %eax, %edi
  movl $0x2000001, %eax           # exit (return value of the call to write())
  syscall

并且能够将返回值捕获到eax。这里的返回值是write系统调用实际写入的字节数。是的，MacOS 是一个 BSD 变体，它是一个进位标志，它告诉你系统调用是否错误（errno 只是一个外部链接变量）。

# hello_asm.s
# as hello_asm.s -o hello_asm.o
# ld hello_asm.o -e _main -o hello_asm
.section __DATA,__data
str:
        .asciz "Hello world!\n"
good:
        .asciz "OK\n"

.section __TEXT,__text
.globl _main
_main:
        movl $0x2000004, %eax           # preparing system call 4
        movl $5, %edi                   # STDOUT file descriptor is 5
        movq str@GOTPCREL(%rip), %rsi   # The value to print
        movq $13, %rdx                  # the size of the value to print
        syscall

        jc err

        movl $0x2000004, %eax           # preparing system call 4
        movl $1, %edi                   # STDOUT file descriptor is 1
        movq good@GOTPCREL(%rip), %rsi  # The value to print
        movq $3, %rdx                   # the size of the value to print
        syscall
        movl $0, %edi
        movl $0x2000001, %eax           # exit 0
        syscall
err:    
        movl $1, %edi
        movl $0x2000001, %eax           # exit 1
        syscall

由于使用了描述符 5，这将退出并显示错误代码 1，如果您尝试使用描述符 1，那么它将打印另一条消息并以 0 退出。