连接读写 Perl 配置文件

Question

我正在使用我在以下网站上找到的 PerlMonk 示例： Reading and Writing Perl Config Files

配置.pl：

%CFG = (
    'servers' => {
        'SRV1' => {
            'IP'     => 99.32.4.0,
            'user'   => 'aname',
            'pswd'   => 'p4ssw0rd',
            'status' => 'unavailable'
        },
        'SRV2' => {
            'IP'     => 129.99.10.5
            'user'   => 'guest',
            'pswd'   => 'guest'
            'status' => 'unavailable'
        }
    },
    'timeout' => 60,
    'log' => {
        'file'  => '/var/log/my_log.log',
        'level' => 'warn',
    },
    'temp' => 'remove me'
);

它工作得很好，但唯一的问题是在读取和写入类似 HASH 的配置时“无序”。 有没有办法让它保持绑定？

这很重要，因为配置文件也会手动编辑，所以我希望键和值的顺序相同。

Answer 1

您可以在使用之前tie 配置变量，因此以后的哈希键将保持与以前相同的顺序，

use strict;
use warnings;

use Tie::IxHash;
tie my %CFG, 'Tie::IxHash';

%CFG = (
    'servers' => {
        'SRV1' => {
            'IP'     => '99.32.4.0',
            'user'   => 'aname',
            'pswd'   => 'p4ssw0rd',
            'status' => 'unavailable'
        },
        'SRV2' => {
            'IP'     => '129.99.10.5',
            'user'   => 'guest',
            'pswd'   => 'guest',
            'status' => 'unavailable'
        }
    },
    'timeout' => 60,
    'log' => {
        'file'  => '/var/log/my_log.log',
        'level' => 'warn',
    },
    'temp' => 'remove me'
);

use Data::Dumper;
print Dumper \%CFG;

Answer 2

如果您使用JSON，那么您的优势是您的软件可以免受恶意攻击（或可能是意外损坏）。 JSON 的语法也比 Perl 数据结构更简单，更容易从语法错误中恢复。

设置canonical 选项将创建具有排序顺序的键的数据，因此每次都为相同的 Perl 数据生成相同的输出。如果您需要按字母顺序以外的特定顺序的数据，那么您可以使用@mpapec 在他的回答中描述的Tie::IxHash 模块。

或者，您可以使用纯 Perl 版本的模块中的 sort_by 方法，该方法允许您传递排序规则子例程。这可以让您指定键的顺序，并且可以像使用将所有可能的键值与数字排序顺序相关联的哈希一样简单。

此程序使用sort_by 方法以与原始哈希中键出现的顺序相同的顺序重构 JSON。这不太可能是您想要的顺序，但机制就在那里。它通过查找哈希表中的每个键来确定它们应该如何排序。默认情况下，未出现在哈希中的任何键（如 SVR1 和 SVR2 此处）按字母顺序排序。

use strict;
use warnings;

use JSON::PP ();

my %CFG = (
  'servers' => {
    'SRV1' => {
      'IP'     => '99.32.4.0',
      'user'   => 'aname',
      'pswd'   => 'p4ssw0rd',
      'status' => 'unavailable'
    },
    'SRV2' => {
      'IP'     => '129.99.10.5',
      'user'   => 'guest',
      'pswd'   => 'guest',
      'status' => 'unavailable'
    }
  },
  'timeout' => 60,
  'log'     => {
    'file'  => '/var/log/my_log.log',
    'level' => 'warn',
  },
  'temp' => 'remove me'
);

my %sort_order;
my $n = 0;
$sort_order{$_} = ++$n for qw/ servers timeout log temp /;
$sort_order{$_} = ++$n for qw/ IP user pswd status /;
$sort_order{$_} = ++$n for qw/ file level /;

my $json = JSON::PP->new->pretty->sort_by(\&json_sort);
print $json->encode(\%CFG);

sub json_sort {
  my ($aa, $bb) = map $sort_order{$_}, $JSON::PP::a, $JSON::PP::b;
  $aa and $bb and $aa <=> $bb or $JSON::PP::a cmp $JSON::PP::b;
}

产生这个输出

{
   "servers" : {
      "SRV1" : {
         "IP" : "99.32.4.0",
         "user" : "aname",
         "pswd" : "p4ssw0rd",
         "status" : "unavailable"
      },
      "SRV2" : {
         "IP" : "129.99.10.5",
         "user" : "guest",
         "pswd" : "guest",
         "status" : "unavailable"
      }
   },
   "timeout" : 60,
   "log" : {
      "file" : "/var/log/my_log.log",
      "level" : "warn"
   },
   "temp" : "remove me"
}

可以简单地保存到文件中并以类似方式恢复。