Clojure ^:const 是如何工作的？

Question

我试图了解 ^:const 在 clojure 中的作用。这就是开发文档所说的。 http://dev.clojure.org/display/doc/1.3

(定义常量 {:pi 3.14 :e 2.71})

(def ^:const pi (:pi 常数)) (def ^:const e (:e 常量))

在映射中查找 :e 和 :pi 的开销发生在编译时，因为 (:pi 常量) 和 (:e 常量) 在它们的父 def 形式被求值时被求值。

这令人困惑，因为元数据是针对绑定到符号 pi 的 var 和绑定到符号 e 的 var，但下面的句子说它有助于加快地图查找，而不是 var 查找。

有人可以解释^:const 在做什么以及使用它的理由吗？这与使用巨大的 let 块或使用像 (pi) 和 (e) 这样的宏相比如何？

Answer 1

在示例文档中，他们试图表明，在大多数情况下，如果您 def 一个 var 是在不使用 const 的情况下在地图中查找某些内容的结果，那么查找将在类加载时发生。 所以每次运行程序时都要支付一次费用（不是在每次查找时，只是在类加载时）。并支付每次读取时在 var 中查找值的成本。

如果您改为将其设为 const，则编译器将在编译时进行查找，然后发出一个简单的 java final 变量，您只需在编译时支付一次查找费用程序。

这是一个人为的例子，因为在类加载时进行一次 map 查找和在运行时进行一些 var 查找基本上什么都不是，尽管它说明了一些工作发生在编译时，一些工作发生在加载时，其余的很好.. . 其余时间

Answer 2

这对我来说似乎是一个糟糕的例子，因为关于地图查找的东西只会混淆这个问题。

一个更现实的例子是：

(def pi 3.14)
(defn circ [r] (* 2 pi r))

在这种情况下，圆周的主体被编译成在运行时取消引用 pi 的代码（通过调用 Var.getRawRoot），每次调用圆周。

(def ^:const pi 3.14)
(defn circ2 [r] (* 2 pi r))

在这种情况下，circ2 被编译成完全相同的代码，就好像它是这样编写的：

(defn circ2 [r] (* 2 3.14 r))

也就是说，跳过了对 Var.getRawRoot 的调用，这样可以节省一点时间。这是一个快速测量，其中 circ 是上面的第一个版本，而 circ2 是第二个：

user> (time (dotimes [_ 1e5] (circ 1)))
"Elapsed time: 16.864154 msecs"
user> (time (dotimes [_ 1e5] (circ2 1)))
"Elapsed time: 6.854782 msecs"

Answer 3

除了上述效率方面，还有一个安全方面也很有用。考虑以下代码：

(def two 2)
(defn times2 [x] (* two x))
(assert (= 4 (times2 2)))    ; Expected result

(def two 3)                  ; Ooops! The value of the "constant" changed
(assert (= 6 (times2 2)))    ; Used the new (incorrect) value

(def ^:const const-two 2)
(defn times2 [x] (* const-two x))
(assert (= 4 (times2 2)))    ; Still works

(def const-two 3)            ; No effect!
(assert (= 3 const-two ))    ; It did change...
(assert (= 4 (times2 2)))    ; ...but the function did not.

因此，通过在定义变量时使用 ^:const 元数据，变量被有效地“内联”到每个使用它们的地方。因此，对 var 的任何后续更改都不会影响已内联“旧”值的任何代码。

^:const 的使用还具有文档功能。当阅读 (def ^:const pi 3.14159) 时，它会告诉读者 var pi 永远不会改变，它只是值 3.14159 的一个方便（并且希望是描述性的）名称。

---

说了以上所有，请注意我从不在我的代码中使用^:const，因为它具有欺骗性并提供“虚假保证”，即 var 永远不会改变。问题是^:const 意味着不能重新定义变量，但正如我们在const-two 中看到的那样，它不会阻止变量被更改。相反，^:const 隐藏了 var 具有新值的事实，因为在更改 var 之前（在运行时）const-two 已被复制/内联（在编译时）到每个使用位置。

更好的解决方案是在尝试更改 ^:const 变量时抛出异常。