如何在 TCL 中跟踪日志文件

Question

假设有一个文件 log.txt 并且某种日志被永久附加到它上面。

我想在 TCL 环境中跟踪那个文件。

我试过了，但是没用。

set log [open log.txt a]

for { } { true } { update; after 1000 } {

    # expected to get here the appended part
    read $log

    seek $log 0 end

}

是否可以通过相同的文件句柄log读取修改后的文件，或者我必须关闭并重新打开文件log.txt？

在 TCL 中有没有一种相当于 Linux 命令tail -f 的东西？

Answer 1

只需使用tail。它比你更了解如何处理复杂的情况（你可以看它的源码）。

在我的一个项目中，我有这样的东西来监控由专有工具生成的跟踪文件：

set fd [open [list | tail --follow=name --retry --lines 0 $opt(trace) 2>@1]]
chan event $fd readable [list FollowTrace $fd]

proc FollowTrace fd {
  if {[gets $fd line] < 0} {
    set code [catch {close $fd} err]
    if {$code == 0} {
      set ::result 0
    } else {
      puts stderr $err
      set ::result 1
    }
    return
  }

  switch -regexp -matchvar parts -- $line {
    {Tm_Session::Open.*FileName=([^,]+)} {
       TryMakeLock [FullPathname [lindex $parts 1]]
     }
     {Tm_Session::Close.*FileName=([^,]+)} {
        StartUpload [lindex $parts 1]
     }
  }
}

一般的想法是在给定文件上生成tail，然后进入事件循环并逐行处理tail的输出。

Answer 2

您已经不远了，只需解决一些问题：

1. 在这段代码中，您是从文件中读取，而不是附加到它，其他一些进程会这样做，因此应该以读取模式打开文件，而不是附加模式，即。从 open 命令中删除“a”选项。
2. 在开始阅读之前，您应该只查找文件末尾一次，否则您将跳过稍后添加的内容，因此将查找命令移到循环之前。
3. 在发布的代码中，您没有对阅读的文本做任何事情 - 我将举一个例子，将其写回标准输出。

4. 如果您在循环中的处理涉及更新 gui 或其他需要事件循环的东西，您只需要 update 命令 - 发布的代码不需要它。 总而言之：

   set log [open log.txt]
   seek $log 0 end
   
   for { } { true } { after 1000 } {
   
       # expected to get here the appended part
       puts -nonewline [read $log]
   }
   

Answer 3

我已经设法在纯 Tcl 上编写了 tail -f 等效项。代码如下：

proc readHandler {handle} {
    puts -nonewline [read $handle]
    flush stdout
    # to reduce CPU overhead...
    after 1000
}

set hFile [open "file.log" "r"]
# seek to the end of file if needed
# seek $hFile 0 end 

fconfigure $hFile -buffering none -eofchar "" -blocking no
fileevent $hFile readable [subst {readHandler $hFile}]

#just for exiting into main event loop
vwait forever