CMake：为 ctest 设置环境变量（或者自动从 ctest/make test 获取失败的测试输出）

Question

我希望 ctest 默认显示失败的测试输出。也就是我要跑：

$ make all test

无需cat Testing/Temporary/LastTest.log即可查看失败测试的任何输出。

似乎有两种方法可以做到这一点：

(1)设置CTEST_OUTPUT_ON_FAILURE环境变量：

 $ CTEST_OUTPUT_ON_FAILURE=1 make all test
 $ # or CTEST_OUTPUT_ON_FAILURE=1 ctest

(2) 为ctest 调用指定--output-on-failure 标志：

 $ ctest --output-on-failure

有没有办法编写一个 CMakeLists.txt 文件，这样 ctests 在正常的“make all test”调用中默认转储失败的测试输出，而无需在会话中全局导出环境变量或使用自定义目标，如make check（如here所述）？

我知道SET_TESTS_PROPERTIES() 命令，但尝试如下：

CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
PROJECT(testenv CXX)
ENABLE_TESTING()
ADD_EXECUTABLE(hello hello.cpp)
ADD_TEST(testhello hello)

# Following sets the environment variable for the shell in which the test
# progoram 'hello' is run, but not the shell in which ctest is run
SET_TESTS_PROPERTIES(testhello
    PROPERTIES ENVIRONMENT "CTEST_OUTPUT_ON_FAILURE=1")

并且实验表明环境变量是在执行测试程序的shell中设置的，而不是在执行ctest的shell中。

Answer 1

无法修改内置的test 目标，但您可以添加自定义check 目标，该目标通过--output-on-failure 开关调用ctest，方式如下：

if (CMAKE_CONFIGURATION_TYPES)
    add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} 
        --force-new-ctest-process --output-on-failure 
        --build-config "$<CONFIGURATION>")
else()
    add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} 
        --force-new-ctest-process --output-on-failure)
endif()

对于单一构建类型和多配置构建，必须以不同方式设置自定义目标。在后一种情况下，必须使用--build-config 标志将活动构建配置传递给ctest 调用。 --force-new-ctest-process 被内置的test 目标默认使用。

Answer 2

现在有列表变量CMAKE_CTEST_ARGUMENTS，您可以在其中设置 ctest 参数。

https://cmake.org/cmake/help/latest/variable/CMAKE_CTEST_ARGUMENTS.html