FireDac FDQuery 在浏览结果时提交更改的 DataFields

Question

我有一个绑定到 FDConnection 的 FDQuery。

我正在使用 DB Data-Aware 组件在我的表单上显示数据。

每当我使用 FPQuery.Next、.Prior、...时，它都会在结果之间浏览。

一切正常。

除非我更改了一个值（例如 John -> Jane）然后使用 FPQuery.Next 来获取下一个结果，它保存将更改的值提交到数据库，即使我没有 FDQuery1.CommitUpdates。

有没有办法只在用户按下 nbPost-Button 或使用 FDQuery1.CommitUpdates 时保存更改的 DataFields 而不是在浏览结果时保存？

谢谢！

Answer 1

就像我在评论中所说，标准的TDataset 行为是调用其.Post 方法来保存对当前行的更改，然后再导航到另一行。这发生在Data.DB.Pas 中的例程TDataSet.CheckBrowseMode 中，该例程在任何导航操作之前调用。如果不派生自定义 TDataset 后代，则无法更改此设置。

（来自 Data.DB.Pas）

procedure TDataSet.CheckBrowseMode;
begin
  CheckActive;
  DataEvent(deCheckBrowseMode, 0);
  case State of
    dsEdit, dsInsert:
      begin
        UpdateRecord;
        if Modified then Post else Cancel;
      end;
    dsSetKey:
      Post;
  end;
end;

当然，TDataSet 有一个BeforePost 事件，因此尝试使用它来取消更改可能很诱人；但是，BeforePost 的问题是如何确定调用它的上下文，以便能够判断它是否是从CheckBrowseMode 调用的，而不是用户单击保存按钮的结果。

解决这个问题的简单方法是捕获DBNavigator 的BeforeAction 事件，然后它调用数据集上的导航操作，这将触发.Post：

procedure TForm1.DBNavigator1BeforeAction(Sender: TObject; Button:
    TNavigateBtn);
var
  Res : Integer;
  DataSet : TDataSet;
begin
  DataSet := DBNavigator1.DataSource.DataSet;
  case Button of
    nbFirst,
    nbPrior,
    nbNext,
    nbLast: begin
      if DataSet.State in [dsEdit, dsInsert] then begin
        Res := MessageDlg('The current row has unsaved changes.  Abandon them?', mtWarning, [mbYes, mbNo], 0);
        if Res = mrYes then
          DataSet.Cancel
        else
          DataSet.Post;
      end;
    end;
  end;
end;

Answer 2

很好的答案MartynA。

如果您不想限制导航器组件并且通常进行此类检查，您可以像这样覆盖 TFDQuery.InternalPost：

procedure TFDQuery.InternalPost;
begin
  if State in [dsEdit, dsInsert] then
  begin
    if MessageDlg('Save changes?', mtWarning, [mbYes, mbNo], 0) = mrNo then
      Cancel();
  end;

  inherited;
end;