由于您提供了对问题的更新，并且 cmets 建议您禁用使用 MASM PROC 指令创建的函数的序言和尾声代码生成，我怀疑您的代码看起来像这样：
.MODEL FLAT, STDCALL
OPTION PROLOGUE:NONE
OPTION EPILOGUE:NONE
.CODE
__MyMemcpy PROC _dest : DWORD, _source : DWORD, _size : DWORD
MOV EDI, DWORD PTR [ESP + 04H]
MOV ESI, DWORD PTR [ESP + 08H]
MOV ECX, DWORD PTR [ESP + 0CH]
PUSH ESI
PUSH EDI
__AGAIN:
LODSB
STOSB
LOOP __AGAIN
POP EDI
POP ESI
RETN 0CH
__MyMemcpy ENDP
END
关于此代码的注释：请注意，如果您的源缓冲区和目标缓冲区重叠，这可能会导致问题。如果缓冲区不重叠，那么您正在做的事情应该有效。您可以通过标记指针__restrict 来避免这种情况。 __restrict 是一个 MSVC/C++ 扩展，它将作为对编译器的提示，即参数不与另一个重叠。这可能允许编译器潜在地警告这种情况，因为您的汇编代码对于这种情况是不安全的。你的原型可以写成：
extern void __stdcall __MyMemcpy( void* __restrict, void* __restrict, int);
typedef struct {
void(__stdcall* MemCpy)(void* __restrict, void* __restrict, int);
}MemFunc;
您正在使用PROC，但没有利用它提供（或隐藏）的任何潜在功能。您已使用 OPTION 指令禁用 PROLOGUE 和 EPILOGUE 生成。您正确地使用了RET 0Ch 从堆栈中清除了 12 个字节的参数。
从 STDCALL 调用约定的角度来看，您的代码是正确的，因为它与堆栈使用有关。存在一个严重的问题，即 Microsoft Windows STDCALL calling convention 要求调用者保留它使用的所有寄存器，除了 EAX、ECX 和 EDX。您破坏了 EDI 和 ESI 并且两者都需要在使用之前保存。在您的代码中，您可以在它们的内容被破坏后保存它们。您必须先将 ESI 和 EDI 都压入堆栈。这将要求您将相对于 ESP 的偏移量添加 8。你的代码应该是这样的：
__MyMemcpy PROC _dest : DWORD, _source : DWORD, _size : DWORD
PUSH EDI ; Save registers first
PUSH ESI
MOV EDI, DWORD PTR [ESP + 0CH] ; Arguments are offset by an additional 8 bytes
MOV ESI, DWORD PTR [ESP + 10H]
MOV ECX, DWORD PTR [ESP + 14H]
__AGAIN:
LODSB
STOSB
LOOP __AGAIN
POP ESI ; Restore the caller (non-volatile) registers
POP EDI
RETN 0CH
__MyMemcpy ENDP
您询问了为什么您似乎收到有关 ESP 或堆栈问题的错误。我假设您收到类似于此的错误：
这可能是由于在混合 STDCALL 和 CDECL 调用约定时 ESP 不正确，也可能是由于保存的 ESP 的值被功能。在您的情况下，它似乎是后者。
我用这段代码编写了一个小型 C++ 项目，其行为与您的 C 程序类似：
#include <iostream>
extern "C" void __stdcall __MyMemcpy( void* __restrict, void* __restrict, int);
typedef struct {
void(__stdcall* MemCpy)(void* __restrict, void* __restrict, int);
}MemFunc;
int initmemfunc(MemFunc* f) {
f->MemCpy = __MyMemcpy;
return 0;
}
char buf1[] = "Testing";
char buf2[200];
int main()
{
MemFunc mf = { 0 };
initmemfunc(&mf);
mf.MemCpy(buf2, buf1, strlen(buf1));
std::cout << "Hello World!\n" << buf2;
}
当我使用像您这样无法正确保存 ESI 和 EDI 的代码时，我在 Visual Studio C/C++ 调试器中显示的生成的汇编代码中发现了这一点：
我已经注释了重要的部分。编译器已生成 C 运行时检查（这些可以禁用，但它们只会隐藏问题而不修复它），包括跨 STDCALL 函数调用的 ESP 检查。不幸的是，它依赖于将 ESP 的原始值（在推送参数之前）保存到寄存器 ESI 中。因此，在调用 __MyMemcpy 后会进行运行时检查，以查看 ESP 和 ESI 是否仍然是相同的值。如果不是，您会收到关于 ESP 未正确保存的警告。
由于您的代码错误地破坏了ESI（和EDI），因此检查失败。我已经对调试输出进行了注释，希望能提供更好的解释。
您可以避免使用LODSB/STOSB 循环来复制数据。有一条指令就是这个操作 (REP MOVSB) 复制 ESI 指向的 ECX 字节并将它们复制到 EDI。您的代码的一个版本可以写成：
__MyMemcpy PROC _dest : DWORD, _source : DWORD, _size : DWORD
PUSH EDI ; Save registers first
PUSH ESI
MOV EDI, DWORD PTR [ESP + 0CH] ; Arguments are offset by an additional 8 bytes
MOV ESI, DWORD PTR [ESP + 10H]
MOV ECX, DWORD PTR [ESP + 14H]
REP MOVSB
POP ESI ; Restore the caller (non-volatile) registers
POP EDI
RETN 0CH
__MyMemcpy ENDP
如果您要使用PROC 的强大功能来保存寄存器ESI 和EDI，您可以使用USES 指令列出它们。您还可以按名称引用堆栈上的参数位置。您还可以通过简单地使用ret 让 MASM 为调用约定生成正确的 EPILOGUE 序列。这将适当地清理堆栈，并且在 STDCALL 返回的情况下，通过从堆栈中删除指定数量的字节（即ret 0ch）在这种情况下，因为有 3 个 4 字节参数。
缺点是您必须生成 PROLOGUE 和 EPILOGUE 代码，这会使事情变得更加低效：
.MODEL FLAT, STDCALL
.CODE
__MyMemcpy PROC USES ESI EDI dest : DWORD, source : DWORD, size : DWORD
MOV EDI, dest
MOV ESI, source
MOV ECX, size
REP MOVSB ; Use instead of LODSB/STOSB+Loop
RET
__MyMemcpy ENDP
END
汇编器会为你生成这个代码：
PUBLIC __MyMemcpy@12
__MyMemcpy@12:
push ebp
mov ebp,esp ; Function prologue generate by PROC
push esi ; USES caused assembler to push EDI/ESI on stack
push edi
mov edi,dword ptr [ebp+8]
mov esi,dword ptr [ebp+0Ch]
mov ecx,dword ptr [ebp+10h]
rep movs byte ptr es:[edi],byte ptr [esi]
; MASM generated this from the simple RET instruction to restore registers,
; clean up stack and return back to caller per the STDCALL calling convention
pop edi ; Assembler
pop esi
leave
ret 0Ch
有些人可能正确地争辩说，让汇编器掩盖所有这些工作会使代码可能更难理解，因为这些人没有意识到 MASM 可以使用 PROC 声明的函数进行特殊处理。这可能会导致将来更难为不熟悉 MASM 细微差别的其他人维护代码。如果您不了解 MASM 可能会生成什么，那么坚持自己编写函数的主体可能是一个更安全的选择。正如您所发现的，这还涉及关闭 PROLOGUE 和 EPILOGUE 代码生成。