什么是安全呼叫？答案

【问题标题】：What's safecall?什么是安全呼叫？
【发布时间】：2010-09-10 21:30:22
【问题描述】：

我正在使用 VB6 创建一个 ActiveX EXE，我得到的唯一示例都是用 Delphi 编写的。

阅读示例代码，我注意到有些函数的签名后跟 safecall 关键字。这是一个例子：

function AddSymbol(ASymbol: OleVariant): WordBool; safecall;

这个关键字的目的是什么？

【问题讨论】：

en.wikipedia.org/wiki/X86_calling_conventions#safecall>

标签： delphi calling-convention

【解决方案1】：

在 COM 中，每个方法都是一个返回 HRESULT 的函数：

IThingy = interface
   ['{357D8D61-0504-446F-BE13-4A3BBE699B05}']
   function AddSymbol(ASymbol: OleVariant; out RetValue: WordBool): HRESULT; stdcall;
end;

这是 COM 中的绝对规则：

COM 中没有异常
一切都返回 HRESULT
负 HRESULT 表示失败
在高级语言中，失败被映射到异常

COM 设计者的意图是，高级语言会自动将 Failed 方法转换为异常。

因此，在您自己的语言中，COM 调用将在没有 HRESULT 的情况下表示。例如：

类似德尔福：function AddSymbol(ASymbol: OleVariant): WordBool;
类 C#：WordBool AddSymbol(OleVariant ASymbol);

在 Delphi 中，您可以选择使用原始函数签名：

IThingy = interface
   ['{357D8D61-0504-446F-BE13-4A3BBE699B05}']
   function AddSymbol(ASymbol: OleVariant; out RetValue: WordBool): HRESULT; stdcall;
end;

并自己处理引发的异常：

bAdded: WordBool;
thingy: IThingy;
hr: HRESULT;

hr := thingy.AddSymbol('Seven', {out}bAdded);
if Failed(hr) then
    OleError(hr);

或更短的等价物：

bAdded: WordBool;
thingy: IThingy;
hr: HRESULT;

hr := thingy.AddSymbol('Seven', {out}bAdded);
OleCheck(hr);

或更短的等价物：

bAdded: WordBool;
thingy: IThingy;

OleCheck(thingy.AddSymbol('Seven'), {out}bAdded);

COM 不打算让你处理 HRESULT

但您可以要求 Delphi 将管道隐藏起来，以便您继续编程：

IThingy = interface
   ['{357D8D61-0504-446F-BE13-4A3BBE699B05}']
   function AddSymbol(ASymbol: OleVariant): WordBool; safecall;
end;

在幕后，编译器仍会检查返回的 HRESULT，如果 HRESULT 指示失败（即是否定的），则抛出 EOleSysError 异常。编译器生成的 safecall 版本在功能上等同于：

function AddSymbol(ASymbol: OleVariant): WordBool; safecall;
var
   hr: HRESULT;
begin
   hr := AddSymbol(ASymbol, {out}Result);
   OleCheck(hr);
end;

但它让你可以简单地调用：

bAdded: WordBool;
thingy: IThingy;

bAdded := thingy.AddSymbol('Seven');

tl;dr：您可以使用任一：

function AddSymbol(ASymbol: OleVariant; out RetValue: WordBool): HRESULT; stdcall;
function AddSymbol(ASymbol: OleVariant): WordBool; safecall;

但前者要求您每次都处理 HRESULT。

奖金聊天

您几乎不想自己处理 HRESULT；它使程序杂乱无章，并没有增加任何噪音。但有时您可能想自己检查 HRESULT（例如，您想处理不是非常特殊的故障）。从来没有版本的 Delphi 开始包含以两种方式声明的已翻译的 Windows 标头接口：

IThingy = interface
   ['{357D8D61-0504-446F-BE13-4A3BBE699B05}']
   function AddSymbol(ASymbol: OleVariant; out RetValue: WordBool): HRESULT; stdcall;
end;

IThingySC = interface
   ['{357D8D61-0504-446F-BE13-4A3BBE699B05}']
   function AddSymbol(ASymbol: OleVariant): WordBool); safecall;
end;

或来自 RTL 来源：

  ITransaction = interface(IUnknown)
    ['{0FB15084-AF41-11CE-BD2B-204C4F4F5020}']
    function Commit(fRetaining: BOOL; grfTC: UINT; grfRM: UINT): HResult; stdcall;
    function Abort(pboidReason: PBOID; fRetaining: BOOL; fAsync: BOOL): HResult; stdcall;
    function GetTransactionInfo(out pinfo: XACTTRANSINFO): HResult; stdcall;
  end;

  { Safecall Version }
  ITransactionSC = interface(IUnknown)
    ['{0FB15084-AF41-11CE-BD2B-204C4F4F5020}']
    procedure Commit(fRetaining: BOOL; grfTC: UINT; grfRM: UINT); safecall;
    procedure Abort(pboidReason: PBOID; fRetaining: BOOL; fAsync: BOOL); safecall;
    procedure GetTransactionInfo(out pinfo: XACTTRANSINFO); safecall;
  end;

SC 后缀代表 safecall。这两个接口是等效的，您可以根据需要选择声明 COM 变量的方式：

//thingy: IThingy;
thingy: IThingySC;

你甚至可以在它们之间投射：

thingy: IThingSC;
bAdded: WordBool;

thingy := CreateOleObject('Supercool.Thingy') as TThingySC;

if Failed(IThingy(thingy).AddSymbol('Seven', {out}bAdded) then
begin
   //Couldn't seven? No sixty-nine for you
   thingy.SubtractSymbol('Sixty-nine');
end;

额外奖励聊天 - C#

C# 默认情况下相当于 Delphi safecall，但在 C# 中除外：

您必须选择退出安全调用映射
而不是选择加入

在 C# 中，您可以将 COM 接口声明为：

[ComImport]
[Guid("{357D8D61-0504-446F-BE13-4A3BBE699B05}")]
[InterfaceType(ComInterfaceType.InterfaceIsIUnknown)]
public interface IThingy
{
   WordBool AddSymbol(OleVariant ASymbol);
   WordBool SubtractSymbol(OleVariant ASymbol);
}

您会注意到 COM HRESULT 对您隐藏。 C#编译器和Delphi编译器一样，会自动检查返回的HRESULT并为你抛出异常。

在 C# 中，与在 Delphi 中一样，您可以选择自己处理 HRESULT：

[ComImport]
[Guid("{357D8D61-0504-446F-BE13-4A3BBE699B05}")]
[InterfaceType(ComInterfaceType.InterfaceIsIUnknown)]
public interface IThingy
{
   [PreserveSig]
   HRESULT AddSymbol(OleVariant ASymbol, out WordBool RetValue);

   WordBool SubtractSymbol(OleVariant ASymbol);
}

[PreserveSig] 告诉编译器按原样保留方法签名：

指示具有 HRESULT 或 retval 返回值的非托管方法是直接转换还是 HRESULT 或 retval返回值会自动转换为异常。

【讨论】：

【解决方案2】：

此外，异常防火墙通过使用支持 IErrorInfo 的对象调用 SetErrorInfo() 来工作，以便调用者可以获得有关异常的扩展信息。这是由 TComObject 和 TAutoIntfObject 中的 TObject.SafeCallException 覆盖完成的。这两种类型都实现了 ISupportErrorInfo 来标记这一事实。

如果发生异常，safecall方法的调用者可以查询ISupportErrorInfo，然后查询其方法导致失败的接口HRESULT（高位设置），如果返回S_OK，GetErrorInfo()可以得到异常信息（描述、帮助等，形式为 IErrorInfo 实现，由 Delphi RTL 在 SafeCallException 覆盖中传递给 SetErrorInfo()）。

【讨论】：

【解决方案3】：

What Francois said 如果不是安全调用，您的 COM 方法调用将如下所示，您必须自己进行错误检查而不是获取异常。

function AddSymbol(ASymbol: OleVariant; out Result: WordBool): HResult; stdcall;

【讨论】：

【解决方案4】：

Safecall 从右到左传递参数，而不是从左到右传递帕斯卡或寄存器（默认）

使用safecall，过程或函数在返回时从堆栈中删除参数（类似于pascal，但不像cdecl，它取决于调用者）

Safecall 实现异常“防火墙”；特别是在 Win32 上，这实现了进程间 COM 错误通知。否则它将与 stdcall 相同（与 win api 一起使用的其他调用约定）

【讨论】：