有没有比 xsl:variable 更好的方法来引用 XPath 表达式中的属性值？

Question

我正在使用 XSLT 2.0 来转换一些 XML。源 XML 类似于：

<AnimalTest>
  <AnimalTypes>
    <AnimalType name="cat"/>
    <AnimalType name="dog"/>
  </AnimalTypes>
  <Animals>
    <Animal name="Sylvester" typeName="cat"/>
    <Animal name="Fido" typeName="dog"/>
    <Animal name="Tom" typeName="cat"/>
  </Animals>
</AnimalTest>

在处理AnimalType 标记的XSL 模板中，我想在XPath 表达式中使用AnimalType 的name 属性。我能够实现这一点的唯一方法是引入一个包含属性@name 并从 XPath 表达式内部引用的变量，如下所示：

<xsl:template match="AnimalType">
  <xsl:variable name="typename" select="@name"/>
  <xsl:apply-templates select="/AnimalTest/Animals/Animal[@typeName=$typename]"/>
</xsl:template>

这可行，但我想知道我是否真的必须使用这个临时变量。有没有更好的方法来引用 @name 属性？对我来说似乎是绕道而行。

Answer 1

如果您真的不喜欢使用该变量，您可以使用 current() 函数来引用当前上下文节点（在您的情况下为 AnimalType）

<xsl:apply-templates select="/AnimalTest/Animals/Animal[@typeName=current()/@name]"/>

如果您有一个更复杂的表达式，使用变量可以提高可读性，并且您可能会在其他地方重复使用。

需要注意的一点是他的声明

<xsl:variable name="typename" select="@name"/>

和这个声明不太一样

<xsl:variable name="typename">
   <xsl:value-of select="@name" />
</xsl:variable>

虽然两个变量将包含相同的值。在后一种情况下（使用 xsl:value-of），您正在创建 name 属性值的副本。在前一种情况下，您直接引用属性。因此使用后一种格式效率会降低。

顺便说一句，您可以考虑在此处使用键来按类型名称查找您的 Animal 元素

<xsl:key name="AnimalByType" match="Animal" use="@typeName" />

这样，您的 apply-templates 表达式可以简化为以下内容

<xsl:template match="AnimalType">
   <xsl:apply-templates select="key('AnimalByType', @name)"/>
</xsl:template>