如何枚举vim中的选项卡？

Question

Vim 是一个非常高效的编辑器，我每天都喜欢使用它，但我发现在标签之间移动花费的时间比它应该的要多。

当我想切换到另一个标签时，我经常重复gt 或gT 多次。 Vim 提供了一种更好的方式来访问所需的选项卡 - n + gt，其中 n 是选项卡编号。但是要使用它，您应该先计算标签号。如果您打开十几个标签，它很快就会变得无聊。

我认为枚举选项卡会很好。文件名前面每个选项卡上的单个数字，如下所示：

1 Readme | 2 main.c | 3 main.h | 4 process.h

我希望可以通过编辑配置或使用一些插件来配置 vim 来做到这一点。

有办法实现吗？

Answer 1

您可以使用tabline 选项在vim 的控制台模式下设置选项卡的标签。 请参阅:h setting-tabline 的帮助，其中还显示了一个非常基本的最小示例，您可以根据需要对其进行调整，例如对于你想要的，我会使用这样的东西：

fu! MyTabLabel(n)
let buflist = tabpagebuflist(a:n)
let winnr = tabpagewinnr(a:n)
let string = fnamemodify(bufname(buflist[winnr - 1]), ':t')
return empty(string) ? '[unnamed]' : string
endfu

fu! MyTabLine()
let s = ''
for i in range(tabpagenr('$'))
" select the highlighting
    if i + 1 == tabpagenr()
    let s .= '%#TabLineSel#'
    else
    let s .= '%#TabLine#'
    endif

    " set the tab page number (for mouse clicks)
    "let s .= '%' . (i + 1) . 'T'
    " display tabnumber (for use with <count>gt, etc)
    let s .= ' '. (i+1) . ' ' 

    " the label is made by MyTabLabel()
    let s .= ' %{MyTabLabel(' . (i + 1) . ')} '

    if i+1 < tabpagenr('$')
        let s .= ' |'
    endif
endfor
return s
endfu
set tabline=%!MyTabLine()

Answer 2

如果您使用的是gvim：

set guitablabel=(%N)\ %t\ %M

---

输入 :help tabline 和 :help guitablabel 以了解更多信息。

文档中有function MyTabLine()。