NASM（64 位 linux）：我的“puts”程序不适用于我的“strlen”程序

Question

作为前言，我在 64 位 Linux 操作系统上运行它，因此我使用的是 64 位 Linux 系统调用。

我的strlen 过程以rdi 为参数，并返回rax 中字符串excluding \0 的长度。 （您必须输入一个以 \0 结尾的字符串）。我已经测试过这个程序并且知道它可以正常工作。

我的puts 过程将rdi 作为其参数，使用strlen 获取长度，然后使用write 系统调用。

这是一个（希望是）最小的可重现示例：

section .data
    msg db "HELLO", 10, 0

section .text
    global _start
_start:
    mov  rdi, msg
    call puts
    mov  rax, 0x3c
    xor  rdi, rdi
    syscall

strlen:
    push rdi
    push rcx
    push rsi

    xor rax, rax
    mov rcx, 0xffffffff
    repnz scasb
    jnz .error
    not rcx
    dec rcx
    mov rax, rcx
.return:
    pop rsi
    pop rcx
    pop rdi
    ret
.error:
    mov rax, -1
    jmp .return

puts:
    mov rsi, rdi
    call strlen
    mov rdx, rax
    mov rax, 1
    mov rdi, rax
    syscall
    ret

我真的很困惑为什么这不起作用。我的puts 过程实际上只是一个简单的系统调用，所以我真的不知道这里出了什么问题。

Answer 1

我已经测试过 [my strlen] 并且知道它可以正常工作。

恐怕不行。

mov rcx, 0xffffffff

您似乎认为这会将 rcx 与 -1 一起加载，但事实并非如此：0xffffffff 是 -1 作为 32 位有符号整数，但 rcx 是 64 位寄存器。 （也许您是从某些 32 位代码中复制的？）特别是，mov rcx, 0xffffffff 后跟 not rcx 不会导致 rcx 包含 0，而是 0xffffffff00000000。因此，您的 strlen 返回一个严重错误的值。

将此更改为mov rcx, -1 或mov rcx, 0xffffffffffffffff。