Delphi：拒绝其他进程访问文件答案

【问题标题】：Delphi: deny access to file for other processesDelphi：拒绝其他进程访问文件
【发布时间】：2011-06-18 00:52:22
【问题描述】：

如何拒绝其他进程访问（仅写入）文件？我会一直读\写一个文件。

我用

FileOpen('c:\1.txt', fmOpenReadWrite or fmShareDenyWrite)

但之后（开始将文件加载到 StringList）我得到错误

无法打开文件 C:\1.txt。该进程无法访问该文件，因为它正被其他进程使用。”

只有我打开文件。

【问题讨论】：

您一直在询问有关TFileStream 的问题，这些问题似乎相互冲突。究竟你想做什么？

标签： delphi file

【解决方案1】：

这里的错误信息实际上有点误导。您无法加载到字符串列表的原因是您已经以读/写方式打开了文件。

如果你检查 TStrings.LoadfromFile 的实现：

procedure TStrings.LoadFromFile(const FileName: string);
var
  Stream: TStream;
begin
  Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
  try
    LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

您看到它尝试使用“DenyWrite”条件打开文件，但您已经以写入模式打开了文件。这就是它失败的原因。

您可以改用 LoadFromStream 来解决这个问题。

procedure TForm1.Button1Click(Sender: TObject);
var
  Stream: TStream;
begin
  Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
  try
    Stringlist.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

请注意，您需要使用 fmShareDenyNone 才能在这种情况下工作。再说一次，您可能可以重用从 OpenFile 获得的读/写句柄，可能执行以下操作：

procedure TForm1.Button1Click(Sender: TObject);
var
  Stream: TStream;
  iPosition : Int64;
begin
  Stream := THandleStream.Create(FHandle); //FHandle is the read/write handle returned by OpenFile
  try
    iPosition := Stream.Position;
    Stream.Seek(0, soFromBeginning);
    Stringlist.LoadFromStream(Stream);
    Stream.Position := iPosition;
    //Restore stream position.
  finally
    Stream.Free;
  end;
end;

但请注意，这些方法可能有一些我不知道的“陷阱”。

【讨论】：