使用限制时如何用变量替换包名称

Question

我有两个 Perl 包：pack_hash 和 pack_run

package pack_hash;

$VERSION    = '1.00';
@ISA        = qw( Exporter );
@EXPORT_OK  = qw( %hashInfo );

$hashInfo{abc} = ['a', 'b', 'c'];

1;

---

package pack_run;

use stricts;
use warnings;
use Data::Dumper;
use  pack_hash qw( %hashInfo );

somethingDoing();

sub somethingDoing {
    my $var1 = \%pack_hash::hashInfo;   # getting the hash reference
    print Dumper($var1);
    ...
    ...
}

1;

谁能告诉我，是否可以使用任何变量替换散列包的名称（pack_hash），例如：

my $pakVar = "pack_hash";
my $var1 = \%$pakVar::hashInfo; 

我知道这是 WRONG/NOT_CORRECT，但是当我使用限制时，我想要这种 符号 ref 转换。 我也想知道，是否可以用 eval 来做这件事。但我想要一个最终变量，这里是 $var1，它将引用特定的哈希 (hashInfo)；

Answer 1

不，这是不可能的。但这是：

use strict;
use warnings;
use Symbol qw<qualify_to_ref>;

my $pakVar = 'pack_hash';
my $var1   = *{ qualify_to_ref( 'hashInfo', $pakVar ) }{HASH};

qualify_to_ref 获取包变量的名称和包名称并返回一个 GLOB 引用指针，然后您只需访问 GLOB 的 HASH 槽。你也可以这样做：

my $var1 = \%{ qualify_to_ref( 'hashInfo', $pakVar ) };

但是在非常紧的do 中关闭strict 也同样容易；

my $var1
    = do {
        no strict;
        \%{ $pakVar . '::hashInfo' };
   };

我了解某些编码文化将关闭 strict 或 warnings 视为“作弊”。我知道我有关于在这样的小块中关闭 one 类警告的代码审查问题。我知道我会收到哪些警告，所以我不需要它。审稿人不这么看。

出于这个原因，一些资深的 Perl-ers 对关闭严格没有任何想法。但是如果你不能因为它让当地人不安——你可以使用Symbol。但是，有些商店有针对包变量的规则，所以它永远不会成为问题。

Answer 2

如果你有一个返回哈希引用的类方法：

package pack_hash;
use strict;
use warnings;
our %hashInfo;
$hashInfo{abc} = ['a', 'b', 'c'];
sub hashInfo { \%hashInfo }

那么你可以很容易地得到参考：

use strict;
use warnings;
my $pakVar = 'pack_hash';
my $hashInfo = $pakVar->hashInfo();
print @{ $hashInfo->{'abc'} };