如何确定子字符串的所有单词是否以任何顺序包含在主字符串中？

Question

如何使用 Excel 宏来确定子字符串的所有单词是否以任何顺序包含在主字符串中的真/假？例如，我想检查这个子字符串“ford F150”中的单词是否包含在主字符串“like new f150 ford black”中，它应该返回true。

我尝试了上面的代码示例，但它们不起作用。

我猜测这样做的方法是将子字符串拆分为一个数组，然后检查数组的每个元素是否在主字符串中。如果子字符串的所有元素都在主字符串中，则为真。

我正在使用 VBA 7.1。现在我的宏运行，但无论我搜索什么文本，它总是返回 TRUE。也许这是 InStr 比较方法的问题？也许在数组中存储字符串元素是个问题？这是我的宏：

Sub Macro 1()

Dim MainString As String
Dim SubString As String
Dim SubStringArray() As String
Dim bFound As Boolean

MainString = Cells(1, 1).Text
SubString = Cells(2, 1).Text
SubStringArray() = Split(SubString, " ")
bFound = False

For Each element In SubStringArray
    If InStr(MainString, element) <> 0 Then
    bFound = True
    Exit For
    End If
Next

Cells(1, 7) = bFound

End Sub

我还想确保我不会在“fording”中找到部分匹配项，例如“ford”。我只想检查完整的单词。

Answer 1

假设您说的非部分匹配是搜索文本两侧都有空格的任何内容（即您不想说 "ford" 应该与 " ford." 匹配）那么以下应该工作：

'Macro names cannot contain spaces
'Sub Macro 1()
Sub Macro1()

    Dim MainString As String
    Dim SubString As String
    Dim SubStringArray() As String
    Dim bFound As Boolean

    MainString = UCase(Cells(1, 1).Text) ' use a consistent case so that "F150"
    SubString = UCase(Cells(2, 1).Text)  ' will match "f150"
    SubStringArray() = Split(SubString, " ")
    bFound = True ' Start by assuming that everything will match

    For Each element In SubStringArray
        If InStr(" " & MainString & " ", " " & element & " ") = 0 Then
            'Exit if we have found something that doesn't match
            bFound = False
            Exit For
        End If
    Next

    Cells(1, 7) = bFound

End Sub