以相同的顺序在两个行号之间提取

Question

我有一个包含一列的文件 1：

File 1
apple
pineapple
banana
cherry
kiwi
orange
mango
grape
watermelon

我需要在两个行号之间以相同的顺序提取行的内容，用制表符分隔。例如第 3 行到第 8 行的输出应该是：

Output (Forward)    
banana cherry kiwi orange mango grape

对于第 7 行到第 2 行，输出应为：

Output (reverse)    
mango orange kiwi cherry banana pineapple

我知道用sed 以正向顺序在行之间提取，但反向顺序有问题。

sed '3,8!d'  

Answer 1

我会使用 awk：

awk -v from="7" -v to="2" 'BEGIN{rev=from>to;s=rev?to:from;e=rev?from:to}
NR>=s && NR<=e{r[NR]=$0}
NR>e{
    while(from!=to){
        printf "%s\t",r[from]
        rev?--from:++from
    }
print r[from]
exit}' file

• 使用这个 awk 脚本，您只需提供 from 和 to 变量。如果您提供了颠倒的数字，它会反向打印该范围内的行。将它嵌入到您的 shell 脚本中也很容易，以便从您的 shell 变量中接收 from, to。
• 脚本将在处理max(from,to) 行后中断。例如，如果你的文件有 500 万行，你给 from:2, to:7 脚本只会处理到第 7 行。

对您的输入进行一些测试：

kent$  cat f
apple
pineapple
banana
cherry
kiwi
orange
mango
grape
watermelon

kent$  awk -v from="2" -v to="7" 'BEGIN{rev=from>to;s=rev?to:from;e=rev?from:to}
NR>=s && NR<=e{r[NR]=$0}
NR>e{
        while(from!=to){
                printf "%s\t",r[from]
                rev?--from:++from
        }
print r[from]
exit}' f
pineapple       banana  cherry  kiwi    orange  mango

kent$  awk -v from="7" -v to="2" 'BEGIN{rev=from>to;s=rev?to:from;e=rev?from:to}          
NR>=s && NR<=e{r[NR]=$0}
NR>e{
        while(from!=to){
                printf "%s\t",r[from]
                rev?--from:++from
        }
print r[from]
exit}' f
mango   orange  kiwi    cherry  banana  pineapple

Answer 2

$ cat tst.awk
BEGIN {
    OFS="\t"
    if (beg < end) { min=beg; max=end; delta=+1 }
    else           { min=end; max=beg; delta=-1 }
}
NR >= min { a[NR] = $0 }
NR == max {
    for (i=beg; i!=end; i+=delta) {
        printf "%s%s", a[i], OFS
    }
    print a[end]
    exit
}

$ awk -v beg=3 -v end=8 -f tst.awk file
banana  cherry  kiwi    orange  mango   grape

$ awk -v beg=7 -v end=2 -f tst.awk file
mango   orange  kiwi    cherry  banana  pineapple

Answer 3

我会使用

sed '2,7!d' file1 | tac

tac 只是反向（按行）重复给出的内容。

至于制表符分隔的部分，使用 sed 有很多方法可以做到这一点。其中之一是

sed '2,7!d' | tac | sed '1h; 1!H; $!d; x; s/\n/\t/g'

这会在保持缓冲区中组装完整的输入，然后将其交换到模式空间中并用制表符替换其中的所有换行符：

1h          # first line: save to hold buffer
1!H         # subsequent lines: append to hold buffer
$!d         # if more input is to read, stop here (don't print anything)
x           # otherwise: swap in assembled lines
s/\n/\t/g   # replace newlines with tabs.

您也可以考虑在此步骤中使用 tr，但尾随的换行符使这不像最初想象的那么简单。

或者，您可以使用 sed 一次性完成所有操作：

sed '2,7 { G; x; }; $!d; x; s/\n$//; s/\n/\t/g' file1

这有点棘手：

2,7 {                  # In lines 2 to 7:
  G                    # Append the hold buffer to the pattern space
                       # this is originally a blank line and later the reverse
                       # of the lines already read
  x                    # then swap it back into the hold buffer
}
$!d                    # If the input has not ended, stop here (print nothing)
x                      # When the whole input is consumed, swap the assembled
                       # reverse lines back in
s/\n$//                # remove the trailing newline
s/\n/\t/g              # then replace the newlines with tabs

这有点折腾哪种方法更好。后者在使用 sed 方面仍然有些理智，但更复杂的 sed 脚本的蝙蝠侠解码器环属性已经显示出来。坦率地说，我很伤心，因为我对 sed 情有独钟，在这种情况下考虑放弃 sed 以换取更长但更易读的替代方案（例如awk）并不是一个坏主意：

awk 'NR == 2, NR == 7 { result = $0 sep result; sep = "\t" } END { print result }' file1

Answer 4

以相反的顺序处理行是sed 不适合的任务。由于它作为 流 处理器的特性，它被设计为按正序处理行。

我强烈建议使用awk。虽然基本上即使awk 不提供以相反顺序处理输入文件的功能，但它提供了编程语言功能来缓冲感兴趣的行并在到达停止线后以相反的顺序打印它们：

script.awk：

BEGIN {
    reverse = 0
    if(start>stop) {
        reverse = 1
        start_ = start
        start = stop
        stop = start_
    }
}

NR>=start && NR<=stop {
    buf[NR]=$0
}

NR==stop{
    if(!reverse) {
        for(i=start;i<=stop;i++) {
            printf "%s ",buf[i]
        }
    } else {
        for(i=stop;i>=start;i--) {
            printf "%s\t",buf[i]
        }
    }
    printf "\n"
    exit(0)
}

这样称呼它：

awk -vstart=4 -vstop=9 -f script.awk input.file

或

awk -vstart=3 -vstop=8 -f script.awk input.file

除了awk，您可以使用任何其他您想要的编程语言。