访问 - 使用日期（如果有），否则使用今天的日期

Question

所以这让我发疯了，它应该非常容易做到。我不知道为什么我不能让它工作。 :( 目前我的函数正在计算开始日期和今天日期之间的差异，它工作得很好，但现在我需要实现一个可选的结束日期。所以如果有可用的 EmpEndDate，则应该使用它，否则为今天的日期应该使用。

这是我的功能之一：

Public Function RetentionMonths(ByVal EmpStartDate As Date) As Integer

    Dim RetentionStartdate As Date
    Dim FollowingMonth As Date

        RetentionStartdate = DateAdd("ww", 14, DateAdd("d", vbSaturday - Weekday(EmpStartDate), EmpStartDate))
        FollowingMonth = DateSerial(Year(RetentionStartdate), Month(RetentionStartdate) + 1, 1)
        RetentionMonths = Months(FollowingMonth, Date)

End Function

编辑：Months() 函数

Public Function Months( _
  ByVal datDate1 As Date, _
  ByVal datDate2 As Date, _
  Optional ByVal booLinear As Boolean) _
  As Integer

  Dim intDiff   As Integer
  Dim intSign   As Integer
  Dim intMonths As Integer

  intMonths = DateDiff("m", datDate1, datDate2)

  If DateDiff("d", datDate1, datDate2) > 0 Then
    intSign = Sgn(DateDiff("d", DateAdd("m", intMonths, datDate1), datDate2))
    intDiff = Abs(intSign < 0)
  Else
    intSign = Sgn(DateDiff("d", DateAdd("m", -intMonths, datDate2), datDate1))
    If intSign <> 0 Then
      intDiff = Abs(booLinear)
    End If
    intDiff = intDiff - Abs(intSign < 0)
  End If

  Months = intMonths - intDiff

End Function

我尝试解决这个问题的一种方法：

Public Function RetentionMonths(ByVal EmpStartDate As Date, _
    Optional ByVal EmpEndDate As Date) _
    As Integer

    Dim RetentionStartdate As Date
    Dim FollowingMonth As Date

        RetentionStartdate = DateAdd("ww", 14, DateAdd("d", vbSaturday - Weekday(EmpStartDate), EmpStartDate))
        FollowingMonth = DateSerial(Year(RetentionStartdate), Month(RetentionStartdate) + 1, 1)
        RetentionMonths = Months(FollowingMonth, Nz(EmpEndDate, Date))

End Function

我要么在过去有用的字段中得到疯狂的负数，要么#Name？错误。

Answer 1

您可以使用 clng 检查结束日期的值 0

Public Function RetentionMonths(ByVal EmpStartDate As Date, _
    Optional ByVal EmpEndDate As Date) _
    As Integer

    Dim RetentionStartdate As Date
    Dim FollowingMonth As Date
    Dim tempEndDate As Date

    If CLng(EmpEndDate) = 0 Then EmpEndDate = Now()


        RetentionStartdate = DateAdd("ww", 14, DateAdd("d", vbSaturday - Weekday(EmpStartDate), EmpStartDate))
        FollowingMonth = DateSerial(Year(RetentionStartdate), Month(RetentionStartdate) + 1, 1)
        RetentionMonths = Months(FollowingMonth, Nz(EmpEndDate, Date))

End Function