在 Qt / Qmake 中构建多个目标答案

【问题标题】：Building multiple targets in Qt / Qmake在 Qt / Qmake 中构建多个目标
【发布时间】：2011-01-16 13:58:07
【问题描述】：

如何在 Qt 中指定具有不同配置的多个目标？有没有办法在一个 .pro 文件中做到这一点？

例如，我想构建以下 2 个 .pro 文件（不必每次都手动更改 .pro 文件）：

目标A：

QT += network
TEMPLATE = app
SOURCES += main.cpp \
    mainwindow.cpp
HEADERS += mainwindow.h
FORMS += mainwindow.ui
RESOURCES += resource.qrc

TARGET = targetA
DEFINES += PARAMA

目标B：

  QT += network
  TEMPLATE = app
  SOURCES += main.cpp \
      mainwindow.cpp
  HEADERS += mainwindow.h
  FORMS += mainwindow.ui
  RESOURCES += resource.qrc

  TARGET = targetB
  DEFINES += PARAMB

【问题讨论】：

标签： qt qmake

【解决方案1】：

您可以为一个 .pro 文件定义多个配置：

QT += network
TEMPLATE = app
SOURCES += main.cpp \
    mainwindow.cpp
HEADERS += mainwindow.h
FORMS += mainwindow.ui
RESOURCES += resource.qrc

configA {
TARGET = targetA
DEFINES += PARAMA
}

configB {
  TARGET = targetB
  DEFINES += PARAMB
}

您可以在运行 qmake 时使用 CONFIG 参数。

qmake x.pro CONFIG+=configA

【讨论】：

【解决方案2】：

您可以将两个文件共有的部分移动到单独的 .pri 文件中。之后可以使用包含函数在目标文件中引用公共文件：include(common.pri)

【讨论】：

除此之外，您可以通过配置开关将两部分分开，并在使用 qmake 构建项目时在命令行上发送不同的配置开关。