条件格式空白单元格-VBA

Question

如果 B 列中的单元格小于 F 列中的值，我需要突出显示该单元格。例如，如果单元格 B2 为 10，F2 为 20，则 B2 应为红色。但是在 B 列中有空白单元格，我不希望这些单元格突出显示。例如 B6 为空白，但 F6 为 10。在我的代码中，B6 也变为红色。

另外，我将如何突出显示同一行中已经突出显示的单元格。例如，如果 B2 突出显示，则突出显示 F2。

我的代码如下：

Sub threecf()
    Dim rg As Range
    Dim cond1 As FormatCondition, cond2 As FormatCondition
    Set rg = Range("B2", Range("B2").End(xlDown))

    'clear any existing conditional formatting
    rg.FormatConditions.Delete

    'define the rule for each conditional format
    Set cond1 = rg.FormatConditions.Add(xlCellValue, xlLess, "=f2")
    Set cond2 = rg.FormatConditions.Add(xlCellValue, xlEqual, "=isempty(f2)")

    'define the format applied for each conditional format
    With cond1
      .Interior.Color = vbRed
      .Font.Color = vbWhite
    End With

    With cond2
      .Interior.Color = vbWhite
      .Font.Color = vbWhite
    End With

End Sub

Answer 1

正如我在评论中提到的，使用公式。无需使用VBA

最简单的方式（推荐方式）

我推荐这种方式，因为它考虑了正在添加的新行。

1. 选择列 B
2. 选择主页选项卡 |条件格式 |新规则 |使用公式确定要格式化的单元格
3. 输入公式=AND(B1<F1,B1<>"")
4. 选择格式 |填充标签
5. 将填充颜色设置为红色:)

自定义方式

1. 手动选择单元格 B2 到 col B 中的最后一行
2. 选择主页选项卡 |条件格式 |新规则 |使用公式确定要格式化的单元格
3. 输入公式=AND(B2<F2,B2<>"")
4. 选择格式 |填充标签
5. 将填充颜色设置为红色:)

VBA方式

如果你仍然想要 VBA，那么试试这个

Sub Sample()
    Dim ws As Worksheet
    Dim lRow As Long

    '~~> Change as applicable
    Set ws = Sheet1

    With ws
        lRow = .Range("B" & .Rows.Count).End(xlUp).Row

        With .Range("B2:B" & lRow)
            .FormatConditions.Add Type:=xlExpression, Formula1:="=AND(B2<F2,B2<>"""")"
            .FormatConditions(.FormatConditions.Count).SetFirstPriority

            With .FormatConditions(1).Interior
                .PatternColorIndex = xlAutomatic
                .Color = 255
                .TintAndShade = 0
            End With

            .FormatConditions(1).StopIfTrue = False
        End With
    End With
End Sub

Answer 2

转到条件格式 --> 新规则 --> 使用公式确定要格式化的单元格 --> 粘贴：=IF(AND(B2<F2,B2<>"") = TRUE,1,0)

对于 F 列：=IF(AND(F2>B2,F2<>"") = TRUE,1,0)

Answer 3

如果您想要 VBA 解决方案，请尝试不使用条件格式：

Sub StackOverflow()
    Dim x As Long
    With ThisWorkbook.Sheets("Stack")
        For x = 1 To .Cells.Find("*", SearchOrder:=xlByRows, LookIn:=xlValues, SearchDirection:=xlPrevious).Row
            If .Cells(x, 2).Value <> "" And .Cells(x, 2).Value < .Cells(x, 6).Value Then
                .Cells(x, 2).Interior.Color = vbRed
                .Cells(x, 6).Interior.Color = vbRed
                .Cells(x, 2).Font.Color = vbWhite
                .Cells(x, 6).Font.Color = vbWhite
            Else
                .Cells(x, 2).Interior.Pattern = xlNone
                .Cells(x, 6).Interior.Pattern = xlNone
                .Cells(x, 2).Font.Color = vbBlack
                .Cells(x, 6).Font.Color = vbBlack
            End If
        Next x
    End With
End Sub

根据您的需要调整代码（根据需要更改宏名称、电子表格地址和颜色）。