SUMIFS 对自定义日期范围之间的数据求和

Question

我正在构建一个仪表板来汇总购买数据。我有一个购买数据的工作表，有一个参考表工作表，其中包含财政月的开始和结束日期、相关的财政年度和财政月（总结如下），以及仪表板工作表。

表：oetFiscalMonths

Start Date | End Date | Month    | Year  
10/1/17    | 10/30/17 | October  | 2018  
10/31/17   | 11/1/17  | November | 2018  

在仪表板上有一个格式如下的数据表

         | Beginning Budget | Total Purchases | Remaining Budget |  
October  | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
November | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
December | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
January  | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  

我希望输入的公式将进入总购买量，并将根据财政月份的表格汇总右侧财政月份的所有购买量，同时满足我能够做到的其他几个标准完成SUMIFS 公式。我只是不确定如何处理日期范围部分，因为它们甚至大部分时间都不遵循日历月，并且日期表的格式与其他几个部分使用其当前格式的方式相同。

非常感谢任何帮助！

Answer 1

您也可以通过 sumproduct 公式尝试，它的好处是无需打开工作表公式计算。

=SUMPRODUCT(--(B:B>=H3)*(B:B<=I3),(C:C))

C:C = 总和范围

B:B = 日期搜索范围

H3 = 开始日期的值

I3 = 结束日期的值

Answer 2

假设sheet1是您的仪表板，sheet2包含您的oetFiscalMonths表，sheet3包含您想要SUM的购买及其对应的购买日期，您可以使用SUMIFS结合INDEX + MATCH 以适应您当前的文件结构：

=SUMIFS(sheet3!C:C,sheet3!B:B,">="&INDEX(sheet2!A:A,MATCH(sheet1!A2,sheet2!C:C,0)),sheet3!B:B,"<="&INDEX(sheet2!B:B,MATCH(sheet1!A2,sheet2!C:C,0)))

图例如下：

sheet3!C:C包含您要购买的价值SUM

sheet3!B:B 包含购买日期

sheet2!A:A 包含您月份的开始日期

sheet2!B:B 包含您月份的结束日期

sheet2!C:C 包含您的月份

sheet1!A2 包含您想要获得SUM 购买的第一个月。

Answer 3

您可以使用如下所示的 SUMIFS。请原谅随机行和单元格的使用。我将在下面尝试解释。

=SUMIFS(C:C,A:A,">="&G1,A:A,"<="&H1)

C:C = 总和范围
A:A = 日期搜索范围
G1 = 开始日期的值
H1 = 结束日期的值

编辑： 我建议将月份列移到前面，然后将日期移到后面，如下所示。这样您就可以使用 vlookup 来查找日期，然后将 vlookup 合并到 sumifs 中。

  Month  | Start Date | End Date | Year  
October  | 10/1/17    | 10/30/17 | 2018  
November | 10/31/17   | 11/1/17  | 2018

=SUMIFS(G:G,F:F,">="&VLOOKUP(J6,M:O,2,0),F:F,"<="&VLOOKUP(J6,M:O,3,0))

M:O 是您的会计年度表
J6 是您输入要搜索的月份的位置
第一个 VLOOKUP 中的第 2 列将为您提供开始日期
第二个 VLOOKUP 中的第 3 列将为您提供结束日期


如果您有任何问题，请告诉我，因为我使用的是随机行和列，这可能会有点令人困惑。