不受欢迎的常规 Perlin 噪音答案

【问题标题】：Undesired regular Perlin noise不受欢迎的常规 Perlin 噪音
【发布时间】：2012-11-21 08:11:39
【问题描述】：

我正在尝试将 fBm 实现到行星的球体上。为了创建我的球体，我将它从一个立方体转换为这样的。不幸的是，生成的 fBm 显示为镜像补丁。此外，它只在 2 个面上进行（包装其他面的值）。当呈现为 sphere

时，这会导致类似的拉伸外观

噪声函数是Ken Perlin描述的改进噪声，我为 HLSL 改编了这个：

  float fade(float t) { return t * t * t * (t * (t * 6 - 15) + 10); }

  float lerp(float t, float a, float b) { return a + t * (b - a); }

  float grad(int hash, float x, float y, float z) {
  int h = hash & 15;                      // CONVERT LO 4 BITS OF HASH CODE
  float u = h<8 ? x : y,                 // INTO 12 GRADIENT DIRECTIONS.
         v = h<4 ? y : h==12||h==14 ? x : z;
  return ((h&1) == 0 ? u : -u) + ((h&2) == 0 ? v : -v);
  } 
  int p[512] = { 151,...180 }; //0-255 twice

  float noise(float x, float y, float z) {


  int X = (int)floor(x) & 255;                  // FIND UNIT CUBE THAT
  int Y = (int)floor(y) & 255;                  // CONTAINS POINT.
  int Z = (int)floor(z) & 255;
  x -= floor(x);                                // FIND RELATIVE X,Y,Z
  y -= floor(y);                                // OF POINT IN CUBE.
  z -= floor(z);
  float u = fade(x),                                // COMPUTE FADE CURVES
         v = fade(y),                                // FOR EACH OF X,Y,Z.
         w = fade(z);
  int A = p[X  ]+Y, AA = p[A]+Z, AB = p[A+1]+Z,      // HASH COORDINATES OF
      B = p[X+1]+Y, BA = p[B]+Z, BB = p[B+1]+Z;      // THE 8 CUBE CORNERS,

  return lerp(w, lerp(v, lerp(u, grad(p[AA  ], x  , y  , z   ),  // AND ADD
                                 grad(p[BA  ], x-1, y  , z   )), // BLENDED
                         lerp(u, grad(p[AB  ], x  , y-1, z   ),  // RESULTS
                                 grad(p[BB  ], x-1, y-1, z   ))),// FROM  8
                 lerp(v, lerp(u, grad(p[AA+1], x  , y  , z-1 ),  // CORNERS
                                 grad(p[BA+1], x-1, y  , z-1 )), // OF CUBE
                         lerp(u, grad(p[AB+1], x  , y-1, z-1 ),
                                 grad(p[BB+1], x-1, y-1, z-1 ))));
  }

这个实现在之前的项目中按预期工作，但是对于这个项目，当我使用顶点位置作为输入时，它似乎创建了一个平滑的网格。它是一个单位立方体，所以值不是整数，但我不知道为什么它没有创建典型的 Perlin 噪声纹理。

任何帮助将不胜感激，如果需要，我会提供更多信息。

【问题讨论】：

查看 scrawkblog 版本

标签： c++ hlsl directx-11 perlin-noise

【解决方案1】：

函数无法访问整数 p 数组，因此我假设其中的值未定义。一个快速的解决方法是使数组静态，但这真的很慢。所以现在我需要传入数组。但我遇到了麻烦。

【讨论】：

【解决方案2】：

我在一个 Dx11 行星渲染项目中使用了下面的噪波函数。我也包含了一个 fBm 函数。我在 WebGL 着色器编程网站ShaderToy 上找到了它（用 GLSL 编写）。

它是由网站作者、神一样的 inigo quilez 编写的。

试一试，希望对你有所帮助。所有的功劳都应该归功于 inigo quilez 的工作。将其移植到 HLSL 是微不足道的。我只在着色器模型 5 中进行了测试，但我确信它至少可以在 4 下工作。

// hash based 3d value noise
// function taken from https://www.shadertoy.com/view/XslGRr
// Created by inigo quilez - iq/2013
// License Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.

// ported from GLSL to HLSL

cbuffer cbNoiseParameters
{
    float _rOctaves;
    float _rLacunarity;
    float _rFrequency;
    float _rAmplitude;
    float _rGain;
    float _rOffset;
};

float hash( float n )
{
    return frac(sin(n)*43758.5453);
}

float noise( float3 x )
{
    // The noise function returns a value in the range -1.0f -> 1.0f

    float3 p = floor(x);
    float3 f = frac(x);

    f       = f*f*(3.0-2.0*f);
    float n = p.x + p.y*57.0 + 113.0*p.z;

    return lerp(lerp(lerp( hash(n+0.0), hash(n+1.0),f.x),
                   lerp( hash(n+57.0), hash(n+58.0),f.x),f.y),
               lerp(lerp( hash(n+113.0), hash(n+114.0),f.x),
                   lerp( hash(n+170.0), hash(n+171.0),f.x),f.y),f.z);
}

float fBm( float3 vPt )
{
    float octaves       = _rOctaves;    
    float lacunarity    = _rLacunarity;
    float frequency     = _rFrequency;
    float amplitude     = _rAmplitude;  
    float gain          = _rGain;
    float offset        = _rOffset;
    float value         = 0.f;

    for( int i = 0; i < octaves; ++ i )
    {
        value += noise( vPt * frequency ) * amplitude;

        amplitude *= gain;
        frequency *= lacunarity;
    }

    return value;
}

【讨论】：