在 CMake 的后期构建步骤中将目标文件复制到另一个位置

Question

我有一个动态库，它根据配置获得不同的名称，在 CMake 脚本中指定：

set_target_properties(${name} PROPERTIES OUTPUT_NAME ${outputName}64)
set_target_properties(${name} PROPERTIES DEBUG_OUTPUT_NAME ${outputName}64_d)

最终结果是我在发布和调试版本中获得了不同的名称。我想将生成的库复制到不同的目录作为构建后的步骤，但是 CMake-Fu 的礼物（？）并没有真正对你微笑。

我试过这样做：

GET_TARGET_PROPERTY(origfile mylibrary LOCATION)
STRING(REGEX REPLACE "/" "\\\\" origfile ${origfile})

set(targetfile my_target_path\\${CMAKE_CFG_INTDIR}\\)
STRING(REGEX REPLACE "/" "\\\\" targetfile ${targetfile})

add_custom_command(TARGET mylibrary POST_BUILD
    COMMAND copy ${origfile} ${targetfile}
)

这适用于发布版本，但对于调试源不包括我所期望的 _d。 如何获取目标的输出路径以便复制文件？

注意：从上面的 sn-p 可以看出，这是目前适用于 Windows/Visual Studio，但我希望它也适用于 OS X/Xcode/make。

注意：我需要将该库放置在一个额外的目录中，该目录用作依赖该库的其他几个项目的输出目录，以便这些项目能够在以下位置加载该库运行。可以接受的替代解决方案是能够创建一个执行复制的自定义目标，以便其他项目可以依赖此项目，而该项目又依赖于库。

Answer 1

与其使用过时的LOCATION 属性，不如使用生成器表达式：

add_custom_command(TARGET mylibrary POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:mylibrary> ${targetfile}
)

您也可以通过设置目标属性RUNTIME_OUTPUT_DIRECTORY 直接在目标目录中生成exe，而不是复制它。这具有每个配置选项（例如RUNTIME_OUTPUT_DIRECTORY_DEBUG）。

set_target_properties(mylibrary PROPERTIES
                      RUNTIME_OUTPUT_DIRECTORY_DEBUG <debug path>
                      RUNTIME_OUTPUT_DIRECTORY_RELEASE <release path>
)

更多详情请运行：

cmake --help-property "RUNTIME_OUTPUT_DIRECTORY"
cmake --help-property "RUNTIME_OUTPUT_DIRECTORY_<CONFIG>"

此外，您应该能够始终使用正斜杠作为路径分隔符，即使在 Windows 上也是如此。

Answer 2

在POST_BUILD 命令中使用generator expressions，而不是手动计算输出路径。这些是配置感知的。示例：

add_custom_command(TARGET mylibrary POST_BUILD 
  COMMAND "${CMAKE_COMMAND}" -E copy 
     "$<TARGET_FILE:mylibrary>"
     "my_target_path/$<CONFIGURATION>/$<TARGET_FILE_NAME:mylibrary>" 
  COMMENT "Copying to output directory")

Answer 3

其他答案对我来说不是 100% 清楚...

假设您正在构建一个可执行文件test_base.exe，以下将构建可执行文件，然后将 .exe 复制到基本的“构建”目录：

add_executable(test_base "")
target_sources(test_base
    PRIVATE
        catch_main.cpp
        catch_tests.cpp
        sc_main.cpp
)
target_link_libraries(test_base PRIVATE Catch2 systemc)

add_custom_command(TARGET test_base POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:test_base> ${PROJECT_BINARY_DIR}/test_base.exe
    COMMENT "Created ${PROJECT_BINARY_DIR}/test_base.exe"
)

因此，在此运行后，您的项目将拥有：

<project dir>/build/test_base.exe