CMake错误：找不到包GTest [重复]答案

【问题标题】：CMake Error: Unable to find package GTest [duplicate]CMake错误：找不到包GTest [重复]
【发布时间】：2020-11-10 15:04:06
【问题描述】：

我正在使用 CMake 开发 C/C++ 应用程序。我想在我的项目中使用 GTest 进行单元测试。为此，我决定在我的存储库中使用 GTest 作为 git 子模块。

我的目录层次如下：

/
--include
--lib
  --GoogleTest
--src
--Tests

lib 中的GoogleTest 子目录包含来自官方存储库的 GTest 源代码。

但我无法使用它来测试我的来源。我的仓库根目录下的CMakeLists.txt文件如下：

OPTION (BUILD_UNIT_TESTS "Build unit tests" ON)

if (BUILD_UNIT_TESTS)
    enable_testing ()
    find_package (GTest REQUIRED)
    add_subdirectory (Tests)
endif ()

但我收到错误：

错误：找不到 GTest（缺少：GTEST_LIBRARY GTEST_INCLUDE_DIR GTEST_MAIN_LIBRARY)

当我搜索这个时，有很多与我类似的问题，但没有一个解决我的问题。而且他们的手册非常有限，并没有详细说明它的使用方法。

CMake 能够成功构建目标 GTest，但当我尝试将其用作外部包时无法识别它。

【问题讨论】：

要使用find_package，您必须安装该库。

标签： c++ cmake googletest

【解决方案1】：

您不必手动下载 Gtest git。只需将以下行添加到您的 CMakeLists.txt

# -------- GOOGLE TEST ----------
# Download and unpack googletest at configure time
configure_file(CMakeLists.txt.in googletest-download/CMakeLists.txt)
execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
        RESULT_VARIABLE result
        WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/googletest-download )
if(result)
    message(FATAL_ERROR "CMake step for googletest failed: ${result}")
endif()
execute_process(COMMAND ${CMAKE_COMMAND} --build .
        RESULT_VARIABLE result
        WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/googletest-download )
if(result)
    message(FATAL_ERROR "Build step for googletest failed: ${result}")
endif()

# Prevent overriding the parent project's compiler/linker
# settings on Windows
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)

# Add googletest directly to our build. This defines
# the gtest and gtest_main targets.
add_subdirectory(${CMAKE_CURRENT_BINARY_DIR}/googletest-src
        ${CMAKE_CURRENT_BINARY_DIR}/googletest-build
        EXCLUDE_FROM_ALL)

# The gtest/gtest_main targets carry header search path
# dependencies automatically when using CMake 2.8.11 or
# later. Otherwise we have to add them here ourselves.
if (CMAKE_VERSION VERSION_LESS 2.8.11)
    include_directories("${gtest_SOURCE_DIR}/include")
endif()
# -------------------------------------------------------------------------
enable_testing()
include_directories("${gtest_SOURCE_DIR}/include")

然后将以下行添加到另一个名为 CMakeLists.txt.in 的文件中，该文件位于您的 CMakeLists.txt 文件所在的同一目录中

cmake_minimum_required(VERSION 2.8.2)

project(googletest-download NONE)

include(ExternalProject)
ExternalProject_Add(googletest
        GIT_REPOSITORY    https://github.com/google/googletest.git
        GIT_TAG           release-1.10.0
        SOURCE_DIR        "${CMAKE_CURRENT_BINARY_DIR}/googletest-src"
        BINARY_DIR        "${CMAKE_CURRENT_BINARY_DIR}/googletest-build"
        CONFIGURE_COMMAND ""
        BUILD_COMMAND     ""
        INSTALL_COMMAND   ""
        TEST_COMMAND      ""
        )

它有什么作用？

您添加到主 CMakeLists 的内容将下载 CMakeLists.txt.in 文件中指定版本的 GTest 和 GMock git 项目。然后它将构建这些，并将构建路径包含在您的主项目中。

来源：GoogleTest Git

【讨论】：