如何制作具有多个其他条件的批处理文件？

Question

我想制作一个包含多个 else 条件的批处理文件，并且已经搜索了很多，但我的不工作。我希望该文件检查是否存在两个文件，如果存在则打开其中一个文件。如果两个文件之一不存在，则批处理应比较接下来的两个文件。我的文件是这样的：

IF EXIST "file1.txt" IF EXIST "file2.txt" Goto V1

IF EXIST "file3.txt" IF EXIST "file4.txt" Goto V2

IF EXIST "file5.txt" AND IF EXIST "file6.txt" Goto V3

:V1
cd "folder"
start sample.exe
goto commonexit

:V2
cd "folder2"
start sample2.exe
goto commonexit

:V3
cd "folder3"
start sample3.exe
goto commonexit

:commonexit

这样 cmd 打开并立即关闭。当我注释掉“：commonexit”时，它会打开并通过代码工作，但似乎在双IF条件下（IF ... IF ...）它只关心第二个IF。在它们之间放置一个 AND 运算符并没有帮助。

你们有没有人猜测，可能是什么问题？

编辑： :commonexit 正在工作。我只是不知道 :commonexit 之后的断线会使代码损坏。

Answer 1

更简单更接近原代码：

IF EXIST "file1.txt" IF EXIST "file2.txt" cd "folder" & start sample.exe & goto commonexit

IF EXIST "file3.txt" IF EXIST "file4.txt" cd "folder2" & start sample2.exe & goto commonexit

IF EXIST "file5.txt" IF EXIST "file6.txt" cd "folder3" & start sample3.exe & goto commonexit

rem Put here code that will execute when none of the previous paths execute...

:commonexit

---

编辑：添加了新方法

下面的新方法允许对多个“EXIST 文件名”测试编写有效的“AND”操作，并以类似于多个“ELSE IF”命令的方式链接其中几个测试：

(for /F "skip=1" %%a in ('dir /B file1.txt file2.txt') do break) && (
   echo Both file1.txt and file2.txt exists
   echo Process they here
) || (for /F "skip=1" %%a in ('dir /B file3.txt file4.txt') do break) && (
   echo Both file3.txt and file4.txt exists
   echo Process they here
) || (for /F "skip=1" %%a in ('dir /B file5.txt file6.txt') do break) && (
   echo Both file5.txt and file6.txt exists
   echo Process they here
) || echo Last else

此方法基于for /F 命令返回的“ExitCode”值，如this answer 所述（在退出代码管理部分下方）。该方法可以很容易地扩展到更多文件，只需插入额外的文件名和将“skip=1”值调整为文件数减一。例如：

(for /F "skip=2" %%a in ('dir /B file1.txt file2.txt file3.txt') do break) && (
   echo All file1.txt, file2.txt and file3.txt exists
   echo Process they here
) || (for /F "skip=2" %%a in ('dir /B file4.txt file5.txt file6.txt') do break) && (
   echo All file4.txt, file5.txt and file6.txt exists
   echo Process they here
) || echo Last else

Answer 2

这是一种方法：

@echo  off
if exist "file1.txt" if exist "file2.txt" (
cd "folder"
start sample.exe
goto :EOF
)

if exist "file3.txt" if exist "file4.txt" (
cd "folder2"
start sample2.exe
goto :EOF
)

if exist "file5.txt" if exist "file6.txt" (
cd "folder3"
start sample3.exe
goto :EOF
)

逻辑如下： 检查file1 是否存在，如果存在则检查file2 是否存在，如果存在，cd，执行样本然后goto 文件结束。但是，如果file1 或file2 不存在，它将跳过当前代码块并转到if 的下一行

Answer 3

这是另一种单行解决方案，（拆分为 3 以保持最大 80 个字符的行长度），它使用 Where 命令：

(Where/Q "file1.txt"&&(Where/Q "file2.txt"&&Start /D "folder" "sample.exe"))||(
    Where/Q "file3.txt"&&(Where/Q "file4.txt"&&Start /D "folder2" "sample2.exe"
))||Where/Q "file5.txt"&&Where/Q "file6.txt"&&Start /D "folder3" "sample3.exe"