Inno-Setup 更新 Win7/Vista 中原始用户的 HKCU

Question

我正在尝试将我的应用程序路径添加为使用 Inno Setup 进行 MS Access 安装的受信任位置。我的脚本中有以下几行：

[Registry]
; Add the application folder as a trusted location for Access 2007
Root: HKCU; SubKey: Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}; ValueType: string; ValueName: Path; ValueData: {app}; Check: AccessVersion('2007');
Root: HKCU; SubKey: Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}; ValueType: string; ValueName: Description; ValueData: Grandjean and Braverman applications; Check: AccessVersion('2007');
Root: HKCU; SubKey: Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}; ValueType: dword; ValueName: AllowSubfolders; ValueData: 1; Check: AccessVersion('2007');

这在 Windows XP 和更早版本中运行良好，但在 Vista/Win7 中的用户帐户控制下通常会失败，因为运行安装的（提升的）用户可能与当前登录的用户不同。

我能想到的唯一解决方法是通过ShellExecAsOriginalUser 提取并运行一个 .reg 文件，但这似乎很老套。有没有更好的办法？

理想情况下，我希望为系统上的所有用户添加受信任的位置。

Answer 1

我使用command-line utility reg.exe 对原始用户的 HKCU 进行更新。 Reg.exe 至少从 Win XP 开始就随 Windows 一起提供。由于早期版本的 Windows 可能没有 reg.exe（或者可能由于其他原因无法访问），因此我保留了注册表部分行以提供冗余和回退。

它仍然有点老套，但我认为它比任何其他替代品都要好。以下是使用这种方法的问题的线条：

[Registry]
; Add the application folder as a trusted location for Access 2007 for the installing user (degrades gracefully for Windows 2000 and earlier)
Root: HKCU; SubKey: Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}; ValueType: string; ValueName: Path; ValueData: {app}; Check: AccessVersion('2007');
Root: HKCU; SubKey: Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}; ValueType: string; ValueName: Description; ValueData: Grandjean and Braverman applications; Check: AccessVersion('2007');
Root: HKCU; SubKey: Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}; ValueType: dword; ValueName: AllowSubfolders; ValueData: 1; Check: AccessVersion('2007');

[Run]
; Add the application folder as a trusted location for Access 2007 for the current user
Filename: Reg.exe; Parameters: "add ""HKCU\Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}"" /v Path /t REG_SZ /d ""{app}"" /f"; Flags: runasoriginaluser; Check: AccessVersion('2007'); StatusMsg: Adding trusted location...
Filename: Reg.exe; Parameters: "add ""HKCU\Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}"" /v Description /t REG_SZ /d ""Grandjean and Braverman applications"" /f"; Flags: runasoriginaluser; Check: AccessVersion('2007'); StatusMsg: Adding trusted location...
Filename: Reg.exe; Parameters: "add ""HKCU\Software\Microsoft\Office\12.0\Access\Security\Trusted Locations\{#DirName}"" /v AllowSubfolders /t REG_DWORD /d 1 /f"; Flags: runasoriginaluser; Check: AccessVersion('2007'); StatusMsg: Adding trusted location...

请注意，这些行已从 [Registry] 部分复制并修改为 [Run] 部分，并设置了标志 runasoriginaluser。

Answer 2

针对您的特定情况的一个解决方案是创建不需要提升权限的第二个设置，仅用于更新注册表。

您可以将第二个安装可执行文件包含在第一个可执行文件中，并使用已经提到的 ShellExecuteAsOriginalUser 使用 /verysilent 命令行参数调用它。

对于您的第二个问题，您必须将其作为不同的问题发布，我不是访问专家，但也许您可以进行整机配置，将相同的值添加到 HKLM 注册表项。

我的 5 美分。