批处理加载器问题

Question

我正在用一些花哨的东西制作批处理游戏。我知道你可以让它弹出消息等，但我感兴趣的是一个不同的弹出窗口：我想做一个加载器。

例如，在您完成一项任务后，此加载程序将弹出。 装载机完成后，批处理将继续。我正在尝试制作类似于以下之一的加载器：

这与 (MSG) 命令的弹出样式相同。我想指定这个加载栏的标题。批处理可以吗？有没有办法用.VBS 做到这一点？

这就是我在批处理中生成其他弹出窗口的方式：

echo X=MsgBox("Message Description",0+16,"Title") >msg.vbs

Answer 1

你可以试试这样的：

在名为 loadbar.bat 的文件中，复制以下内容：

@echo off
setlocal EnableDelayedExpansion

set max=16
SET "var="&for /f "delims=0123456789" %%i in ("%2") do set "var=%%i"
if not defined var if not "%~2"=="" set "max=%~2"
title Loading... 
if not "%~3"=="" title "%~3"
color 0a
set "top=É"
set "spaces="
set "bottom=È"
for /L %%i in (1,1,%max%) do (
   set "top=!top!Í"
   set "spaces=!spaces! "
   set "bottom=!bottom!Í"
)
set "top=!top!»"
set "bottom=!bottom!¼"

set /A loadnum=0, loadNum1=max-1
set "load="

:Loading
set "load=%load%²"
(
cls
echo                                 Loading "%~1"
echo                                 %top%
echo                                 º%load%!spaces:~0,%loadnum1%!º
echo                                 %bottom%
)
ping localhost -n 2 >nul
set /A loadnum+=1, loadnum1-=1
if %loadnum% lss %max% goto Loading

cls
timeout 1 >nul
title
color
exit

在您的游戏中，您可以像这样显示加载栏：

@echo off
start /wait loadbar "executing breach..." 5 "executing breach"
pause

loadbar的第一个参数是进度条上面的文字，第二个是最大数，第三个是标题。