vba 运行其他excel文件宏

Question

我有以下代码：

Sub MacroRunner()
Dim Nomefile As String, Nomefolder As String
Nomefolder = ActiveWorkbook.Path

Nomefile = Dir(Nomefolder & "\*.xlsb")
Workbooks.Open (Nomefolder & "\" & Nomefile)
ActiveWorkbook.Worksheets(2).Select
Application.Run "Nomefile!listaIdprodotto"  '<-------- "nomefile" variable not returned

Application.DisplayAlerts = False
ActiveWindow.Close
End Sub

问题在由左箭头标记的行中； Excel 不返回变量值，导致自身无法找到要执行的宏。 感谢您的帮助。

Answer 1

你应该有点不同的引用（如果 Nomefile.xlsb 是文件）：

Application.Run "'Nomefile.xlsb'!listaIdprodotto" 

甚至（如果Nomefile 是一个变量）：

Application.Run "'" & Nomefile & "'!listaIdprodotto"

Source

Answer 2

最好更具体地说明您要处理的文件和工作表。

Nomefolder = ActiveWorkbook.Path
这不一定是包含代码的工作簿。如果您在运行代码之前立即创建一个新工作簿，那么这将等于一个空字符串 - 它是当前位于顶部（活动）的任何工作簿。

Nomefile = Dir(Nomefolder & "\*.xlsb")
这将返回文件夹中具有xlsb 扩展名的第一个文件。如果没有创建今天的文件，它将返回上一个文件并再次运行昨天的更新。
如果它是每天生成的文件，则查找具有正确日期的文件名。

ActiveWorkbook.Worksheets(2).Select
再次 - ActiveWorkbook 的同样问题。这也正在查看标签顺序中的第二张工作表，如果有人移动它，它可能不是您想要的工作表。按名称引用工作表（仍可更改）。最好通过用户无法更改的工作表 CodeName 进行引用，但这会打开一个不同的蠕虫水壶，因为您引用的工作表不在包含代码的工作簿中。

Application.Run "Nomefile!listaIdprodotto"
当您将Nomefile 括在双引号中时，它不会将其视为变量，而是将其视为名为Nomefile 的文件。要将其视为变量，需要将其写为Application.Run Nomefile & "!listaIdprodotto"。如果文件名包含空格，则需要按照 Vityata 所写的方式编写：Application.Run "'" & Nomefile & "'!listaIdprodotto"。这将文件名括在单引号中。

我将代码重写为：

Public Sub Test()

    Dim Nomefile As String, Nomefolder As String
    Dim wrkBk As Workbook

    'Nomefolder = ActiveWorkbook.Path
    Nomefolder = ThisWorkbook.Path
    'Nomefile = Dir(Nomefolder & "\*.xlsb")
    Nomefile = Nomefolder & "\WorkbookWithCode.xlsb"

    'Open the workbook, run the code and close the workbook.
    Set wrkBk = Workbooks.Open(Nomefile)
    Application.Run "'" & wrkBk.Name & "'!listaIdprodotto"
    wrkBk.Close

End Sub

这里的主要区别是我将整个工作簿设置为一个变量 - Set wrkBk = ....。从那以后，我总是可以参考正确的工作簿，而不必担心它是否活动。