InStr : 跳过第一次获取

Question

我正在使用 VBA 并使用 InStr 检查我的文件 .txt 中是否有一些模式，但我不关心我在所有文件中获得的第一个模式。我怎样才能在我得到的第一个循环中跳过所有循环。

在条目中，我有一个包含一些 .txt 文件的文件夹（包含 2000/9000 行），我有一个符号名称列表，我需要检查每个文件中是否有每个符号以及每个文件有多少个符号.这一步现在完成了，但符号文件中的第一次出现我并不感兴趣，因为它只是声明了符号，但它不是符号。因此，要计算 this.txt 文件中此类符号的数量，我必须删除我得到的第一个符号

For i = 2 To Filepath_size

    Open Filepath(i) For Input As #IndexFile
    Debug.Print "Open file: "; Filepath(i)
        Do While Not EOF(IndexFile)
        Line Input #IndexFile, LineContent
        If (InStr(LineContent, LinePrefix)) Then          
            For Each SymbolName In rngSymbo
                If (InStr(LineContent, SymbolName)) Then            
                    Set SymbolLineIndex = Range("A:A").Find(SymbolName, lookat:=xlWhole)            
                    Cells(SymbolLineIndex.Row, i + 1).Interior.ColorIndex = 4 
                    Cells(SymbolLineIndex.Row, i + 1).Value = Cells(SymbolLineIndex.Row, i + 1).Value + 1
                    Cells(SymbolLineIndex.Row, i + 1).Font.Size = 20  
                End If 
            Next SymbolName 
        End If
        Loop
Close #IndexFile
    Next i

我一周前开始使用 VBA，所以我完全不知道这是否可能，但可以跳过 InStr 发现的符号的第一次出现。目前，我的代码每次遇到符号时都会算我一次，也就是说一次比必要的次数太多，并将其显示在我的 sheet1 上的表格上

Answer 1

添加一个计数器，然后检查计数器是否大于1

counter = 0
For i = 2 To Filepath_size

Open Filepath(i) For Input As #IndexFile
Debug.Print "Open file: "; Filepath(i)
    Do While Not EOF(IndexFile)
    Line Input #IndexFile, LineContent
    If (InStr(LineContent, LinePrefix)) Then          
        For Each SymbolName In rngSymbo
            If (InStr(LineContent, SymbolName)) Then   
                counter = counter + 1
                if counter > 1 then
                    Set SymbolLineIndex = Range("A:A").Find(SymbolName, lookat:=xlWhole)            
                    Cells(SymbolLineIndex.Row, i + 1).Interior.ColorIndex = 4 
                    Cells(SymbolLineIndex.Row, i + 1).Value = Cells(SymbolLineIndex.Row, i + 1).Value + 1
                    Cells(SymbolLineIndex.Row, i + 1).Font.Size = 20  
                end if
            End If 
        Next SymbolName 
    End If
    Loop
Close #IndexFile
Next i

Answer 2

更新

下面的例子展示了如何计算文本中每个模式的出现次数：

Option Explicit

Sub TestSplit()

    Dim sSample As String
    Dim aSymbols()
    Dim sSymbol
    Dim a

    sSample = "abc789 def 123 defghi123 abc def 456 789 abc ghi abc 123def 123 456abc789"
    aSymbols = Array("abc", "123", "789")
    For Each sSymbol In aSymbols
        a = Split(sSample, sSymbol)
        Debug.Print "Symbol '" & sSymbol & "': " & UBound(a) & " occurances"
    Next

End Sub

初步回答

这里是一个简单的函数示例，它允许获取文本中第 n 个模式的出现位置：

Option Explicit

Sub Test()

    Debug.Print GetNthInStr("678 abc 123 abc 456", "abc", 1)
    Debug.Print GetNthInStr("678 abc 123 abc 456", "abc", 2)

End Sub

Function GetNthInStr(sText As String, sPattern As String, lNumber As Long) As Long

    Dim i As Long

    GetNthInStr = 0
    For i = 1 To lNumber
        GetNthInStr = InStr(GetNthInStr + 1, sText, sPattern)
        If GetNthInStr = 0 Then Exit For
    Next

End Function