ANTLR 帮助 - 无法解析普通文本，但所有其他更复杂的规则都有效

Question

我有一个非常简单的语法——它解析用户为各种关键字输入的一堆文本，然后对这些关键字进行字符串替换，同时让所有其他文本保持“原样”。

基本上，这个语法对大部分文本都不应该做任何事情......它应该只是回显那个文本......除非它遇到${...}、$video{...}、$image{...}和$audio{...}

我的语法现在大部分都可以使用，但它无法使用 chunk 规则解析像 hey 这样的普通文本，但由于某种原因，它使用 chunk<p>hey</p> /strong> 规则。为什么？如何让两者都使用 chunk 规则？

基本上，我希望 CHUNK 捕获其他规则未拾取的所有其他内容。

我稍微重构了语法以使一切更加清晰。 everythingElse 似乎与 label 混淆了？我不知道，但hey 不起作用:(

grammar Text;

@header {
}

@members {
    int numberOfVideos = 0;
    StringBuilder builder = new StringBuilder();

    public String getResult() {
        return builder.toString();
    }
}

text
    :   expression*
    ;

expression
    :   fillInTheBlank 
        {
            builder.append($fillInTheBlank.value);
        }
    |   image 
        {
            builder.append($image.value);
        }
    |   video
        {
            builder.append($video.value);
        }
    |   audio
        {
            builder.append($audio.value);
        }
    |   anchor
        {
            builder.append($anchor.value);
        }
    |   everythingElse
        {
            builder.append($everythingElse.value);
        }
    ;

fillInTheBlank returns [String value]
    :   '${' LABEL '}' 
        {
            $value = "<input type=\"text\" id=\"" +
                $LABEL.text +
                "\" name=\"" + 
                $LABEL.text +
                "\" class=\"FillInTheBlankAnswer\" />";
        }
    ;

image returns [String value]
    :   '$image{' URL '}'
        {
            $value = "<img src=\"" + $URL.text + "\" />";
        }
    ;

video returns [String value]
    :   '$video{' URL '}'
        {
            numberOfVideos++;

            StringBuilder b = new StringBuilder();
            b.append("<div id=\"video1\">Loading the player ...</div>\r\n");
            b.append("<script type=\"text/javascript\">\r\n");
            b.append("\tjwplayer(\"video" + numberOfVideos + "\").setup({\r\n");
            b.append("\t\tflashplayer: \"/trainingdividend/js/jwplayer/player.swf\", file: \"");
            b.append($URL.text);
            b.append("\"\r\n\t});\r\n");
            b.append("</script>\r\n");

            $value = b.toString();
        }
    ;

audio returns [String value]
    :   '$audio{' URL '}'
        {
            $value = $URL.text;
        }
    ;   

anchor returns [String value]
    :   URL
        {
            $value = "<a href=\"" + $URL.text + "\">" + $URL.text + "</a>";
        }
    ;   

everythingElse returns [String value]
    :   CHUNK
        {
            $value = $CHUNK.text;
        }
    ;

LABEL
    :   ('a'..'z'|'A'..'Z') ('a'..'z'|'A'..'Z'|'0'..'9')*
    ;
URL
    :   'http://' ('a'..'z'|'A'..'Z'|'0'..'9'|'.'|'/'|'-'|'_'|'%'|'&'|'?')+
    ;
CHUNK
    //: (~('${'|'$video{'|'$image{'|'$audio{'))+
    :   ('a'..'z'|'A'..'Z'|'0'..'9'|'-'|' '|','|'.'|'?'|'\''|':'|'\t'|'\n'|'\r'|'\"'|'>'|'<'|'/'|'_'|'='|';'|'('|')'|'&')+
    ;

我是 antlr 的新手 - 使用了大约一天，所以请不要指望我对它了解很多。

Answer 1

由于空间限制和缺乏格式化的可能性，我选择了这种方式来回应。所以，无论如何：

不。 CHUNK 和 LABEL 是 Lexer（扫描器）规则，而 fillInTheBlank 是解析器规则。解析器在扫描器的顶部操作，也就是说，扫描器不知道解析器（规则）。你必须引入lexer states：

首先，您必须引入一个额外的词法分析器成员来保持状态，告诉您是否要读取标签：

@lexer::members {
    private boolean readLabel = false;
}

然后，您必须为修改此状态变量的“${”和“}”（我称它们为 BEGIN_VAR 和 END_VAR）引入显式标记定义。此外，END_VAR 标记只能在 readLabel 为 true 时创建：

BEGIN_VAR
    : '${' { readLabel = true; };

END_VAR : { readLabel }?=> '}' { readLabel = false; };

您还必须告诉词法分析器 LABEL 标记也只能在这种状态下生成：

LABEL
    :   { readLabel }?=> ('a'..'z'|'A'..'Z') ('a'..'z'|'A'..'Z'|'0'..'9')*
    ;

请注意，此定义出现在 CHUNK 之前非常重要。

最后，您必须使用上述令牌定义修改您的 fillInTheBlanks 规则：

fillInTheBlank returns [String value]
    :   BEGIN_VAR LABEL END_VAR 
        { ...

希望这会有所帮助，似乎对我有用。