在 bash 中的 2 个字符串中查找指定字符串

Question

你好， 我有这样的文件：

today#123 
2934
9236
monday 

today#12341
4246
58234
monday

today#456
7768
32347
monday

但在我的文件中大约有 200k+ 行，但它是由以“today”开头并以“Monday”结尾的部分组成的

我可以轻松地将一个或所有部分分开：

awk '/today/ {show=1} show; /monday/ {show=0}' file.txt 

但我不知道如何找到带有特殊字符串的部分（在本例中为 7768） .谁能帮我 ？

1.) 每个部分的行数是随机的

2.) 文件不断变化（每天一次或两次）

结果应该是这样的：

    today#456
    7768
    32347
    monday

谢谢。

Answer 1

关注awk 也可能对您有所帮助。我正在设置一个名为 value 的变量，您可以在其中提供您想要查找的任何值，并且无需更改代码中的任何内容，除了名为 value 的变量的值。

awk -v value="7768" '
/monday/ && flag{
  print;
  flag=val=""
}
/today/{
  val=$0;
  next
}
$0 ~ value{
  flag=1;
  print val RS $0;
  next
}
flag && val
'    Input_file

输出如下。

today#456
7768
32347
Monday

解释：现在也为上面的代码添加解释。

awk -v value="7768" '  ##Creating a variable named value where OP could define its variable value which OP wants to search in any line.
/monday/ && flag{      ##Searching for a string monday in any line and variable flag is NOT NULL then do following:
  print;               ##printing the current line then.
  flag=val=""          ##Nullifying the values of variable flag and val here.
}
/today/{               ##Searching for a string today here if it is found on any line then do following.
  val=$0;              ##Assigning current line value to variable val here.
  next                 ##next is out of the box keyword of awk it will skip all further statements from here.
}
$0 ~ value{            ##Checking condition here if any line value is equal to variable value then do following:
  flag=1;              ##Making variable flag value to 1 or in other words making flag value to TRUE here.
  print val RS $0;     ##Printing the value of variable val with RS(record separator, whose default value is a new line) and current line then.
  next                 ##Mentioning next will skip all further statements now.
}
flag && val            ##checking condition here if variable flag and val is NOT NULL then do following.
'  Input_file          ##mentioning Input_file name here.

Answer 2

使用 awk ：

awk 'show && c{
        if(show=$1==7768)print c;
        c=""
     }
     show;
     /monday/{
         show=0
     }
    /today/{
         show=1;
         c=$0
    }
    ' infile

输出：

$ awk 'show && c{if(show=$1==7768)print c;c=""}show;/monday/{show=0}/today/{show=1;c=$0}' infile
today#456
7768
32347
monday

输入：

$ cat infile
today#123 
2934
9236
monday 

today#12341
4246
58234
monday

today#456
7768
32347
monday

Answer 3

您可以为此编写一个 bash 脚本，例如 recordfinder.sh。它可能如下所示：

# cat recordfinder.sh
#!/bin/bash
exitfn(){
echo "Usage : recordfinder.sh <filename> <searchstring>"
[ "$1" -eq 1 ] && echo "Couldn't open file" && exit 1
[ "$1" -eq 2 ] && echo "No search string provided" && exit 2
}
[ -f "$1" ] || exitfn 1
[ -z "$2" ] && exitfn 2 
awk -v str="$2" -v RS="" '$0 ~ str'  "$1"

# ./recordfinder.sh filename 7768
today#456
7768
32347
monday

希望它能给你一些灵活性:-)

Answer 4

                    sed -n '/today/{:a;/monday/{/\n4246\n/p;b};N;ba}'
                         ^     ^     ^    ^          ^    ^ ^  ^  ^
                         |     |     |    |          |    | |  |  |
dont print all lines-----+     |     |    |          |    | |  |  |
                               |     |    |          |    | |  |  |
if found start of block (today)+     |    |          |    | |  |  |
  then start loop with label (a)-----+    |          |    | |  |  |
  if found end of block (monday)----------+          |    | |  |  |
    then check if patterm (4246) found---------------+    | |  |  |
      if found, then print this buffer--------------------+ |  |  |
    break the loop------------------------------------------+  |  |
  load another line into buffer--------------------------------+  |
  and loop (goto label (a))---------------------------------------+

测试：

$ sed -n '/today/{:a;/monday/{/\n4246\n/p;b};N;ba}' <sample.txt 
today#12341
4246
58234
monday